UTL_TCP

UTL_TCP 패키지의 기본 개념과 패키지 내의 프러시저와 함수를 사용하는 방법을 설명합니다.

개요

UTL_TCP은 TCP/IP 클라이언트 역할을 수행할 수 있는 프러시저 및 함수들을 제공하는 패키지입니다.

많은 인터넷 환경이 TCP/IP 프로토콜에 기반하므로, 이메일이나 인터넷 연결 등에 유용하게 사용될 수 있 다.

타입

본 절에서는 UTL_TCP 패키지에 제공하는 별도 정의된 타입들을 알파벳 순으로 설명합니다.

CONNECTION

UTL_TCP를 이용한 TCP/IP 연결의 객체 및 연결 정보를 담고 있는 레코드 타입입니다.

CONNECTION 타입의 세부 내용은 다음과 같습니다.

프로토타입

TYPE CONNECTION IS RECORD
(
    pvid         PLS_INTEGER,
    remote_host  VARCHAR2(255),
    remote_port  PLS_INTEGER,
    tx_timeout   PLS_INTEGER
);

필드

필드 이름

설명

pvid

TCP/IP의 연결 객체를 지칭하는 ID
변경하지 않도록 함

remote_host

연결된 TCP 서버의 주소

remote_port

연결된 TCP 서버의 포트 번호

tx_timeout

TCP 통신을 이용한 읽기/쓰기의 시간 제한으로, 제한 시간이 지나면 타임아 웃 에러와 함께 반환 (단위: 초)

NULL : 응답이 올 때까지 기다림
0 : 전송 후 대기 없이 즉시 빠져나옴

상수

CRLF

캐리지 리턴 문자, 라인 피드 문자를 가지는 문자열입니다.

정의

CRLF CONSTANT VARCHAR2(2) := unistr('\000D\000A');

프러시저와 함수

본 절에서는 UTL_TCP 패키지에서 제공하는 프러시저와 함수를 알파벳 순으로 설명합니다.

프러시저/함수 예제의 TCP 송수신 확인을 위해 에코 서버가 필요한 경우, 아래 예시와 같이 생성할 수 있습니다.

본 문서의 예제는 localhost(127.0.0.1)와 포트 61000을 사용하며, 테스트 용도로만 활용하시기 바랍니다.

python3 - <<'PY'
import socket
HOST, PORT = "127.0.0.1", 61000

s = socket.socket()
s.setsockopt(socket.SOL_SOCKET, socket.SO_REUSEADDR, 1)
s.bind((HOST, PORT))
s.listen(50)
print(f"listening on {HOST}:{PORT}")

while True:
    c, a = s.accept()
    data = c.recv(65535)
    if data:
        c.sendall(data)
    c.close()
PY

CLOSE_ALL_CONNECTIONS

세션에서 연결 중인 TCP/IP 연결을 모두 끊는 프러시저입니다.

CLOSE_ALL_CONNECTIONS 프러시저의 세부 내용은 다음과 같습니다.

프로토타입

UTL_TCP.CLOSE_ALL_CONNECTIONS

예제

DECLARE
    c UTL_TCP.CONNECTION;
BEGIN
    c := UTL_TCP.OPEN_CONNECTION('localhost', 61000);
    UTL_TCP.CLOSE_CONNECTION(c);
EXCEPTION WHEN OTHERS THEN
    UTL_TCP.CLOSE_ALL_CONNECTIONS;
END;
/

CLOSE_CONNECTION

연결 중인 TCP/IP 연결을 끊는 프러시저입니다.

CLOSE_CONNECTION 프러시저의 세부 내용은 다음과 같습니다.

프로토타입

UTL_TCP.CLOSE_CONNECTION
(
    c IN OUT NOCOPY connection
)

파라미터

파라미터

설명

기존에 연결된 연결 객체
타입은 UTL_TCP.CONNECTION

예제

DECLARE
    c UTL_TCP.CONNECTION;
BEGIN
    c := UTL_TCP.OPEN_CONNECTION('localhost', 61000);
    UTL_TCP.CLOSE_CONNECTION(c);
END;
/

GET_LINE

원격 TCP 서버로부터 받은 문자열 한 줄을 가져오는 함수입니다. 자세한 내용은 동일한 기능을 수행하는 READ_LINE 함수의 설명을 참고합니다.

GET_LINE 함수의 세부 내용은 다음과 같습니다.

프로토타입

UTL_TCP.GET_LINE
(
        c               IN  OUT NOCOPY   connection,
        remove_crlf     IN              BOOLEAN     DEFAULT FALSE,
        peek            IN              BOOLEAN     DEFAULT FALSE
)
RETURN VARCHAR2;

파라미터

파라미터

설명

기존에 연결된 연결 객체
타입은 UTL_TCP.CONNECTION

remove_crlf

TRUE일 경우 문자열에 포함된 CR/LF 문자열을 제거하여 반환

peek

TRUE일 경우 TCP input queue로부터 읽어온 데이터를 비우지 않고 보존하여 이후 다시 읽어올 경우 같은 데이터를 읽게 됨

반환값

읽어들인 문자열입니다.

예제

SET SERVEROUTPUT ON;

DECLARE
    c UTL_TCP.CONNECTION;
    data VARCHAR2(100);
    rc integer;
BEGIN
    c := UTL_TCP.OPEN_CONNECTION('localhost', 61000);
    rc := UTL_TCP.WRITE_LINE(c, 'GET_LINE_EXAMPLE');
    data := UTL_TCP.GET_LINE(c);

    dbms_output.put_line(data);
    
    UTL_TCP.CLOSE_CONNECTION(c);
END;
/

GET_LINE_EXAMPLE

GET_RAW

원격 TCP 서버로부터 받은 바이너리 데이터를 가져오는 함수입니다. 자세한 내용은 동일한 기능을 수행하 는 READ_RAW 함수의 설명을 참고합니다.

GET_RAW 함수의 세부 내용은 다음과 같습니다.

프로토타입

UTL_TCP.GET_RAW
(
        c               IN  OUT NOCOPY  connection,
        len             IN              PLS_INTEGER DEFAULT 1,
        peek            IN              BOOLEAN     DEFAULT FALSE
)
RETURN RAW;

파라미터

파라미터

설명

기존에 연결된 연결 객체
타입은 UTL_TCP.CONNECTION

len

읽어올 바이너리 데이터의 Byte 개수(기본값: 1)

peek

TRUE일 경우 TCP input queue로부터 읽어온 데이터를 비우지 않고 보존하여 이후 다시 읽어올 경우 같은 데이터를 읽게 됨

반환값

읽어들인 바이너리 데이터입니다.

예제

SET SERVEROUTPUT ON;

DECLARE
    c UTL_TCP.CONNECTION;
    data RAW(100);
    rc INTEGER;
BEGIN
    c := UTL_TCP.OPEN_CONNECTION('localhost', 61000);
    rc := UTL_TCP.WRITE_RAW(c, '0D0A');
    data := UTL_TCP.GET_RAW(c, 10);  /* 10Byte의 문자열을 읽어올 것을 요청 */

    dbms_output.put_line(data);
    
    UTL_TCP.CLOSE_CONNECTION(c);    
END;
/

0D0A

GET_TEXT

원격 TCP 서버로부터 받은 문자열을 가져오는 함수입니다. 자세한 내용은 동일한 기능을 수행하는 READ_TEXT 함수의 설명을 참고합니다.

타임아웃이 설정된 경우 타임아웃 시간까지 기다렸다가 만료되었을 때 TRANSFER_TIMEOUT 예외를 발 생시킨다. 타임아웃이 NULL일 경우에는 무한정 기다리므로 주의하여 사용하도록 합니다.

GET_TEXT 함수의 세부 내용은 다음과 같습니다.

프로토타입

UTL_TCP.GET_TEXT
(
        c               IN  OUT NOCOPY   connection,
        len             IN              PLS_INTEGER DEFAULT 1,
        peek            IN              BOOLEAN     DEFAULT FALSE
)
RETURN VARCHAR2;

파라미터

파라미터

설명

기존에 연결된 연결 객체
타입은 UTL_TCP.CONNECTION

len

읽어올 문자열의 Byte 개수(기본값: 1)

peek

TRUE일 경우 TCP input queue로부터 읽어온 데이터를 비우지 않고 보존하여 이후 다시 읽어올 경우 같은 데이터를 읽게 됨

반환값

읽어들인 문자열입니다.

예제

SET SERVEROUTPUT ON;

DECLARE
    c UTL_TCP.CONNECTION;
    data VARCHAR2(100);
    rc INTEGER;
BEGIN
    c := UTL_TCP.OPEN_CONNECTION('localhost', 61000);

    rc := UTL_TCP.WRITE_TEXT(c, 'TIBEROTMAX', 6); -- TIBERO
    data := UTL_TCP.GET_TEXT(c, 10); /* 10Byte의 문자열을 읽어올 것을 요청 */

    dbms_output.put_line(data);

    UTL_TCP.CLOSE_CONNECTION(c);
END;
/

TIBERO

OPEN_CONNECTION

외부 TCP 서버로의 TCP/IP 연결을 맺는 프러시저입니다.

OPEN_CONNECTION 프러시저의 세부 내용은 다음과 같습니다.

프로토타입

UTL_TCP.OPEN_CONNECTION
(
        remote_host     IN      VARCHAR2,
        remote_port     IN      PLS_INTEGER,
        tx_timeout      IN      PLS_INTEGER DEFAULT NULL
) 
RETURN UTL_TCP.CONNECTION;

파라미터

파라미터

설명

remote_host

연결할 TCP 서버의 주소 이름
NULL이면 localhost로 자동 설정

remote_port

연결할 TCP 서버의 포트 번호

tx_timeout

TCP 통신을 이용한 읽기/쓰기의 시간 제한으로, 제한 시간이 지나면 타임아웃 에러와 함께 반환됨(단위: 초)

NULL: 응답이 올 때까지 기다림
0: 전송 후 대기 없이 즉시 빠져나옴

반환값

TCP/IP 연결 정보를 갖는 UTL_TCP.CONNECTION 타입의 객체입니다.

예제

DECLARE
    c UTL_TCP.CONNECTION;
BEGIN
    c := UTL_TCP.OPEN_CONNECTION('localhost', 61000);
    UTL_TCP.CLOSE_CONNECTION(c);
END;
/

READ_LINE

원격 TCP 서버로부터 받은 문자열 한 줄을 가져오는 함수입니다.

READ_LINE 함수의 세부 내용은 다음과 같습니다.

프로토타입

UTL_TCP.READ_LINE
(
        c               IN  OUT NOCOPY   connection,
        data            IN  OUT NOCOPY   VARCHAR2,
        remove_crlf     IN              BOOLEAN     DEFAULT FALSE,
        peek            IN              BOOLEAN     DEFAULT FALSE
)
RETURN PLS_INTEGER;

파라미터

파라미터

설명

기존에 연결된 연결 객체
타입은 UTL_TCP.CONNECTION

data

읽어들인 문자열

remove_crlf

TRUE일 경우 문자열에 포함된 CR/LF 문자열을 제거하여 반환

peek

TRUE일 경우 TCP input queue로부터 읽어온 데이터를 비우지 않고 보존하여 이후 다시 읽어올 경우 같은 데이터를 읽게 됨

반환값

읽어들인 문자열의 문자 수입니다.

예제

SET SERVEROUTPUT ON;

DECLARE
    c UTL_TCP.CONNECTION;
    data VARCHAR2(100);
    len PLS_INTEGER;
    rc  PLS_INTEGER;
BEGIN
    c := UTL_TCP.OPEN_CONNECTION('localhost', 61000);
    rc := UTL_TCP.WRITE_LINE(c, 'READ_LINE_EXAMPLE');
    len := UTL_TCP.READ_LINE(c, data);
    dbms_output.put_line(len); /* 17 when execute UTL_TCP.READ_LINE(c, data, true); */
    dbms_output.put_line(data);
    
    UTL_TCP.CLOSE_CONNECTION(c);    
END;
/

19
READ_LINE_EXAMPLE

READ_RAW

원격 TCP 서버로부터 받은 바이너리 데이터를 가져오는 함수입니다.

READ_RAW 함수의 세부 내용은 다음과 같습니다.

프로토타입

UTL_TCP.READ_RAW
(
        c               IN  OUT NOCOPY   connection,
        data            IN  OUT NOCOPY   RAW,
        len             IN              PLS_INTEGER DEFAULT 1,
        peek            IN              BOOLEAN     DEFAULT FALSE
)
RETURN PLS_INTEGER;

파라미터

파라미터

설명

기존에 연결된 연결 객체
타입은 UTL_TCP.CONNECTION

data

읽어들인 문자열

len

읽어올 바이너리 데이터의 Byte 개수

peek

TRUE일 경우 TCP input queue로부터 읽어온 데이터를 비우지 않고 보존하여 이후 다시 읽어올 경우 같은 데이터를 읽게 됨

반환값

읽어들인 데이터의 Byte 개수입니다.

예제

SET SERVEROUTPUT ON;

DECLARE
    c UTL_TCP.CONNECTION;
    data RAW(100);
    len PLS_INTEGER;
    rc  PLS_INTEGER;
BEGIN
    c := UTL_TCP.OPEN_CONNECTION('localhost', 61000);
    rc := UTL_TCP.WRITE_RAW(c, '0D0A');
    len := UTL_TCP.READ_RAW(c, data, 10);

    dbms_output.put_line(len);
    dbms_output.put_line(data);
    
    UTL_TCP.CLOSE_CONNECTION(c);
END;
/

2
0D0A

READ_TEXT

원격 TCP 서버로부터 받은 문자열을 가져오는 함수입니다.

READ_TEXT 함수의 세부 내용은 다음과 같습니다.

프로토타입

UTL_TCP.READ_TEXT
(
        c               IN  OUT NOCOPY   connection,
        data            IN  OUT NOCOPY   VARCHAR2,
        len             IN              PLS_INTEGER DEFAULT 1,
        peek            IN              BOOLEAN     DEFAULT FALSE
)
RETURN PLS_INTEGER;

파라미터

파라미터

설명

기존에 연결된 연결 객체
타입은 UTL_TCP.CONNECTION

data

읽어들인 문자열

len

읽어올 문자열의 문자 개수

peek

TRUE일 경우 TCP input queue로부터 읽어온 데이터를 비우지 않고 보존하여 이후 다시 읽어올 경우 같은 데이터를 읽게 됨

반환값

읽어들인 데이터의 Byte 개수입니다.

예제

SET SERVEROUTPUT ON;

DECLARE
    c UTL_TCP.CONNECTION;
    data VARCHAR2(100);
    len PLS_INTEGER;
    rc  PLS_INTEGER;
BEGIN
    c := UTL_TCP.OPEN_CONNECTION('localhost', 61000);
    rc := UTL_TCP.WRITE_TEXT(c, 'TIBEROTMAX', 6);
    len := UTL_TCP.READ_TEXT(c, data, 10);

    dbms_output.put_line(len);
    dbms_output.put_line(data);
    
    UTL_TCP.CLOSE_CONNECTION(c);
END;
/

6
TIBERO

WRITE_LINE

원격 TCP 서버로 한줄의 문자열을 전송하는 함수입니다. 입력문자열 뒤에 새줄 문자열이 붙어서 전송됩니다.

WRITE_LINE 함수의 세부 내용은 다음과 같습니다.

프로토타입

UTL_TCP.WRITE_LINE
(
        c       IN OUT NOCOPY   connection,
        data    IN              VARCHAR2    DEFAULT NULL
)
RETURN PLS_INTEGER;

파라미터

파라미터

설명

기존에 연결된 연결 객체
타입은 UTL_TCP.CONNECTION

data

전송할 문자열

반환값

실제 전송된 데이터의 문자열 개수입니다.

예제

SET SERVEROUTPUT ON;

DECLARE
    c UTL_TCP.CONNECTION;
    data VARCHAR2(100);
    rc integer;
BEGIN
    c := UTL_TCP.OPEN_CONNECTION('localhost', 61000);
    rc := UTL_TCP.WRITE_LINE(c, 'WRITE_LINE_EXAMPLE');
    data := UTL_TCP.GET_LINE(c);

    dbms_output.put_line(data);
    
    UTL_TCP.CLOSE_CONNECTION(c);
END;
/

WRITE_LINE_EXAMPLE

WRITE_RAW

원격 TCP 서버로 바이너리 형태의 데이터를 보내는 함수입니다. WRITE_RAW 함수의 세부 내용은 다음과 같습니다.

프로토타입

UTL_TCP.WRITE_RAW
(
        c       IN OUT NOCOPY   connection,
        data    IN              RAW,
        len     IN              PLS_INTEGER DEFAULT NULL
)
RETURN PLS_INTEGER;

파라미터

파라미터

설명

기존에 연결된 연결 객체
타입은 UTL_TCP.CONNECTION

data

전송할 바이너리 데이터

len

전송할 바이너리 데이터의 Byte 수
NULL이면 데이터 전체를 전송

반환값

실제 전송된 데이터의 Byte 수입니다.

예제

SET SERVEROUTPUT ON;

DECLARE
    c UTL_TCP.CONNECTION;
    data RAW(100);
    rc INTEGER;
BEGIN
    c := UTL_TCP.OPEN_CONNECTION('localhost', 61000);
    rc := UTL_TCP.WRITE_RAW(c, '0D0A'); /* 0d 0a의 hex값을 가진 바이너리 데이터 전송 */
    data := UTL_TCP.GET_RAW(c, 10);

    dbms_output.put_line(data);
    
    UTL_TCP.CLOSE_CONNECTION(c);
END;
/

0D0A

WRITE_TEXT

원격 TCP 서버로 문자열 형태의 데이터를 보내는 함수입니다.

WRITE_TEXT 함수의 세부 내용은 다음과 같습니다.

프로토타입

UTL_TCP.WRITE_TEXT
(
        c       IN OUT NOCOPY   connection,
        data    IN              VARCHAR2,
        len     IN              PLS_INTEGER DEFAULT NULL

)
RETURN PLS_INTEGER;

파라미터

파라미터

설명

기존에 연결된 연결 객체
타입은 UTL_TCP.CONNECTION

data

전송할 문자열 데이터

len

전송할 문자열의 문자 개수
NULL이면 문자열 전체를 전송

반환값

실제 전송된 문자열의 문자 개수입니다.

예제

SET SERVEROUTPUT ON;

DECLARE
    c UTL_TCP.CONNECTION;
    data VARCHAR2(100);
    rc INTEGER;
BEGIN
    c := UTL_TCP.OPEN_CONNECTION('localhost', 61000);

    rc := UTL_TCP.WRITE_TEXT(c, 'TIBEROTMAX', 6); /* TIBEROTMAX 문자열 중 TIBERO 문자열만 전송합니다. */
    data := UTL_TCP.GET_TEXT(c, 10);

    dbms_output.put_line(data);

    UTL_TCP.CLOSE_CONNECTION(c);
END;
/

TIBERO

PreviousUTL_SMTP NextUTL_URL

Last updated 17 days ago

hashtag개요

hashtag타입

hashtagCONNECTION

hashtag상수

hashtagCRLF

hashtag프러시저와 함수

hashtagCLOSE_ALL_CONNECTIONS

hashtagCLOSE_CONNECTION

hashtagGET_LINE

hashtagGET_RAW

hashtagGET_TEXT

hashtagOPEN_CONNECTION

hashtagREAD_LINE

hashtagREAD_RAW

hashtagREAD_TEXT

hashtagWRITE_LINE

hashtagWRITE_RAW

hashtagWRITE_TEXT

개요

타입

CONNECTION

상수

CRLF

프러시저와 함수

CLOSE_ALL_CONNECTIONS

CLOSE_CONNECTION

GET_LINE

GET_RAW

GET_TEXT

OPEN_CONNECTION

READ_LINE

READ_RAW

READ_TEXT

WRITE_LINE

WRITE_RAW

WRITE_TEXT