DBMS_UTILITY

DBMS_UTILITY 패키지의 기본 개념과 패키지 내의 프러시저와 함수를 사용하는 방법을 설명합니다.

개요

DBMS_UTILITY은 여러 가지 유용한 기능들을 제공합니다.

타입

본 절에서는 DBMS_UTILITY 패키지에서 제공하는 별도 정의된 타입들을 알파벳 순으로 설명합니다.

UNCL_ARRAY

문자열의 배열입니다. 문자열의 최대 길이는 227 byte입니다.

UNCL_ARRAY 타입의 세부 내용은 다음과 같습니다.

프로토타입

TYPE uncl_array IS TABLE OF VARCHAR2(227) INDEX BY BINARY_INTEGER;

LNAME_ARRAY

문자열의 배열입니다. 문자열의 최대 길이는 4000byte입니다.

LNAME_ARRAY 타입의 세부 내용은 다음과 같습니다.

프로토타입

TYPE lname_array IS TABLE OF VARCHAR2(4000) INDEX BY BINARY_INTEGER;

MAXNAME_ARRAY

문자열의 배열입니다. 문자열의 최대길이는 32767byte입니다.

MAXNAME_ARRAY 타입의 세부 내용은 다음과 같습니다.

프로토타입

TYPE maxname_array IS TABLE OF VARCHAR2(32767) INDEX BY BINARY_INTEGER;

프러시저와 함수

본 절에서는 DBMS_UTILITY 패키지에서 제공하는 프러시저와 함수를 알파벳 순으로 설명합니다.

COMMA_TO_TABLE

테이블 이름들이 쉼표로 구분되어 나열된 문자열을 분석하여 테이블 이름들을 구성 요소로 하는 인덱스 테이블로 변환하는 프러시저입니다.

COMMA_TO_TABLE 프러시저의 세부 내용은 다음과 같습니다.

프로토타입

DBMS_UTILITY.COMMA_TO_TABLE
(
    list         IN         VARCHAR2,
    tablen       OUT        BINARY_INTEGER,
    tab          OUT        UNCL_ARRAY
);

DBMS_UTILITY.COMMA_TO_TABLE
(
    list         IN         VARCHAR2,
    tablen       OUT        BINARY_INTEGER,
    tab          OUT        LNAME_ARRAY
);

파라미터

파라미터

설명

list

쉼표로 구분되어 있는 테이블 이름들의 목록 문자열
테이블 이름들은 a [. b [. c]][ @ d ]로 설정 (a, b, c, d는 따옴표로 묶이거 나 묶이지 않은 식별자 형태의 문자열)
이때 입력값이 NULL값일 경우에도 콤마(,)로 구분.
예를 들어 입력값이 ',a'거나 'a,'인 경우 각각 앞, 뒤에 NULL 값이 들어온 것으로 간주

tablen

생성되는 이름들의 개수

tab

테이블 이름들을 구성 요소로 갖는 인덱스 테이블
uncl_array와 lname_array를 입력 값으로 받을 수 있음

예제

set serveroutput on;

declare
    tab_len binary_integer;
    tab dbms_utility.uncl_array;
begin
    DBMS_UTILITY.COMMA_TO_TABLE('a,"b".c,d.e.f,g.h@i', tab_len, tab);

    for i in 1..tab_len loop
        dbms_output.put_line(tab(i));
    end loop;
end;
/

a
"b".c
d.e.f
g.h@i

CURRENT_INSTANCE

현재 인스턴스의 instance number를 반환해주는 함수입니다.

CURRENT_INSTANCE 함수의 세부 내용은 다음과 같습니다.

프로토타입

DBMS_UTILTIY.CURRENT_INSTANCE 
RETURN NUMBER;

예제

SELECT dbms_utility.current_instance
FROM   dual;

COMPLIE_SCHEMA

지정된 스키마 안의 모든 프러시저, 함수, 패키지, 뷰, 트리거를 컴파일해 주는 프러시저입니다. 이 프러시저를 호출하는 유저가 지정된 스키마에 대한 recompile 권한이 없으면 원하는 결과를 얻지 못할 수 있습니다.

COMPILE_SCHEMA 프러시저의 세부 내용은 다음과 같습니다.

프로토타입

DBMS_UTILITY.COMPILE_SCHEMA
(
    schema            IN VARCHAR2,
    compile_all       IN BOOLEAN DEFAULT TRUE,
    reuse_setting     IN BOOLEAN DEFAULT FALSE
);

파라미터

파라미터

설명

schema

컴파일할 스키마의 이름

compile_all

TRUE : 스키마의 모든 오브젝트들을 컴파일. (기본값)
FALSE : 스키마 내 INVALID한 상태의 오브젝트들만 컴파일.

reuse_setting

TRUE : 오브젝트의 세션 설정을 재사용
FALSE : 현재 세션의 설정이 적용됨 (기본값)

예제

CREATE TABLE RECOMPILE_TAB (ID NUMBER);
CREATE OR REPLACE PROCEDURE RECOMPILE_PROC IS
    a number;
BEGIN
    select count(*) into a from RECOMPILE_TAB;
END;
/
DROP TABLE RECOMPILE_TAB;
CREATE TABLE RECOMPILE_TAB (ID NUMBER);

set serveroutput on;

DECLARE
    stat VARCHAR2(10);
BEGIN
    select status into stat FROM USER_OBJECTS WHERE OBJECT_NAME = 'RECOMPILE_PROC';

    dbms_output.put_line('status of RECOMPILE_PROC before COMPILE_SCHEMA call: ' || stat);

    DBMS_UTILITY.COMPILE_SCHEMA(USER,FALSE);

    select status into stat FROM USER_OBJECTS WHERE OBJECT_NAME = 'RECOMPILE_PROC';
    dbms_output.put_line('status of RECOMPILE_PROC after COMPILE_SCHEMA call: ' || stat);
END;
/

status of RECOMPILE_PROC before COMPILE_SCHEMA call: INVALID
status of RECOMPILE_PROC after COMPILE_SCHEMA call: VALID

EXEC_DDL_STATEMENT

DDL 명령을 실행하는 기능을 제공하는 함수입니다.

EXEC_DDL_STATEMENT 함수의 세부 내용은 다음과 같습니다.

프로토타입

DBMS_UTILITY.EXEC_DDL_STATEMENT
(
    parse_string    IN VARCHAR2
);

파라미터

파라미터

설명

parse_string

실행할 DDL 명령을 지정하는 VARCHAR2 유형의 입력 인수

예제

DECLARE
 BEGIN
 DBMS_UTILITY.EXEC_DDL_STATEMENT('CREATE TABLE UTIL_EXEC_DDL_TEST (ID NUMBER)');
END;
/

select * from all_objects where object_name='UTIL_EXEC_DDL_TEST';

FORMAT_CALL_STACK

콜 스택의 내용을 문자열로 반환하는 함수입니다. 반환 문자열이 32767bytes를 초과하는 경우 원하는 결과를 얻지 못할 수 있습니다.

FORMAT_CALL_STACK 함수의 세부 내용은 다음과 같습니다.

프로토타입

DBMS_UTILITY.FORMAT_CALL_STACK
RETURN VARCHAR2;

예제

set serveroutput on;

create or replace procedure proc3
as
begin
        dbms_output.put_line (dbms_utility.format_call_stack);
end;
/
create or replace procedure proc2
as
begin
        proc3;
end;
/
create or replace procedure proc1
as
begin
        proc2;
end;
/
begin
        proc1;
end;
/

-- ----- PSM Call Stack -----
-- object      line     object
-- handle      number   name
-- 0x7f50fa3943a8         4 procedure SYS.PROC3
-- 0x7f50fa3942d0         4 procedure SYS.PROC2
-- 0x7f50fa3941f8         4 procedure SYS.PROC1
-- 0x7f50fa394120         2 anonymous block

FORMAT_ERROR_BACKTRACE

BACKTRACE 에러 메시지 문자열을 반환하는 함수입니다. 반환 문자열이 712bytes를 초과하는 경우 원하는 결과를 얻지 못할 수 있습니다.

FORMAT_ERROR_BACKTRACE 함수의 세부 내용은 다음과 같습니다.

프로토타입

DBMS_UTILITY.FORMAT_ERROR_BACKTRACE
RETURN VARCHAR2;

예제

CREATE OR REPLACE PROCEDURE BACKTRACE_EXAMPLE_PR0
IS
    variable positive;
BEGIN
    variable := -1;
END;
/

CREATE OR REPLACE PROCEDURE BACKTRACE_EXAMPLE_PR1 IS
BEGIN
    BACKTRACE_EXAMPLE_PR0 ();
END;
/

CREATE OR REPLACE PROCEDURE BACKTRACE_EXAMPLE_PR2 IS
BEGIN
    BACKTRACE_EXAMPLE_PR1 ();
END;
/

CREATE OR REPLACE PROCEDURE BACKTRACE_EXAMPLE_PR3 IS
BEGIN
    BACKTRACE_EXAMPLE_PR2 ();
END;
/
CREATE OR REPLACE PROCEDURE BACKTRACE_EXAMPLE_PR4 IS
    BEGIN BACKTRACE_EXAMPLE_PR3 ();
END;
/

CREATE OR REPLACE PROCEDURE BACKTRACE_EXAMPLE_PR5 IS
    BEGIN BACKTRACE_EXAMPLE_PR4 ();
END;
/

CREATE OR REPLACE PROCEDURE BACKTRACE_EXAMPLE_PR6 IS
BEGIN
    BACKTRACE_EXAMPLE_PR5 ();
EXCEPTION
    WHEN OTHERS THEN
        DBMS_OUTPUT.PUT_LINE (DBMS_UTILITY.FORMAT_ERROR_BACKTRACE() );
END;
/

set serveroutput on;

begin
    BACKTRACE_EXAMPLE_PR6 ();
end;
/

--  TBR-15163:  Unhandled  exception  at  SYS.BACKTRACE_EXAMPLE_PR0,  line  5. 
--  TBR-15163:  Unhandled  exception  at  SYS.BACKTRACE_EXAMPLE_PR1,  line  3. 
--  TBR-15163:  Unhandled  exception  at  SYS.BACKTRACE_EXAMPLE_PR2,  line  3. 
--  TBR-15163:  Unhandled  exception  at  SYS.BACKTRACE_EXAMPLE_PR3,  line  3. 
--  TBR-15163:  Unhandled  exception  at  SYS.BACKTRACE_EXAMPLE_PR4,  line  2. 
--  TBR-15163:  Unhandled  exception  at  SYS.BACKTRACE_EXAMPLE_PR5,  line  2. 
--  TBR-15163:  Unhandled  exception  at  SYS.BACKTRACE_EXAMPLE_PR6,  line  3.

FORMAT_ERROR_STACK

에러 스택의 내용을 문자열로 반환하는 함수입니다. 반환 문자열이 712bytes를 초과하는 경우 원하는 결과 를 얻지 못할 수 있습니다.

FORMAT_ERROR_STACK 함수의 세부 내용은 다음과 같습니다.

프로토타입

DBMS_UTILITY.FORMAT_ERROR_STACK
RETURN VARCHAR2;

예제

CREATE OR REPLACE PROCEDURE CALLSTACK_EXAMPLE_PR0
IS
    variable positive;
BEGIN
    variable := -1;
END;
/

CREATE OR REPLACE PROCEDURE CALLSTACK_EXAMPLE_PR1
IS
BEGIN
    CALLSTACK_EXAMPLE_PR0 ();
END;
/

CREATE OR REPLACE PROCEDURE CALLSTACK_EXAMPLE_PR2
IS
BEGIN
    CALLSTACK_EXAMPLE_PR1 ();
END;
/

set serveroutput on;

begin
    CALLSTACK_EXAMPLE_PR2 ();
exception when others then
    dbms_output.put_line (DBMS_UTILITY.FORMAT_ERROR_STACK);

    dbms_output.put_line ('exception handled.');
end;
/

-- TBR-15115: Invalid value.
-- TBR-15035: Number is out of range.
-- exception handled.

FORMAT_VM_MM

PSM 엔진에서 사용 중인 psm value와 refv 의 목록을 반환환하는 함수입니다.

FORMAT_VM_MM 함수의 세부 내용은 다음과 같습니다.

프로토타입

DBMS_UTILITY.FORMAT_VM_MM
RETRUUN VARCHAR2

예제

set serveroutput on;

DECLARE
    str varchar2(2000);
BEGIN
    str := DBMS_UTILITY.FORMAT_VM_MM;
    DBMS_OUTPUT.PUT_LINE(str);
END;
/

GET_HASH_VALUE

주어진 문자열의 해시 값을 구하는 함수입니다.

GET_HASH_VALUE 함수의 세부 내용은 다음과 같습니다.

프로토타입

DBMS_UTILITY.GET_HASH_VALUE
(
    name          IN    VARCHAR2,
    base          IN    NUMBER,
    hash_size    IN    NUMBER
)
RETURN NUMBER;

파라미터

파라미터

설명

name

해시 값을 얻고자 하는 문자열

base

해시 값의 시작점

hash_size

해시 테이블의 크기. 크기는 1 이상이어야 함.

예제

set serveroutput on;

declare
    hash_value number;
begin
    hash_value := DBMS_UTILITY.GET_HASH_VALUE('Oleg', 1000, 100);

    dbms_output.put_line(hash_value);
end;
/

-- 1076

GET_TIME

현재 시간을 1/100초 단위의 숫자로 표현하는 함수입니다. 일반적으로 시작과 끝에 호출하여 소요 시간을 측정하는 데 사용됩니다.

GET_TIME 함수의 세부 내용은 다음과 같습니다.

프로토타입

DBMS_UTILITY.GET_TIME
RETURN NUMBER;

예제

set serveroutput on;

declare
    s number;
    e number;
    c sys_refcursor;
begin
    s := DBMS_UTILITY.GET_TIME;
    open c for select * from all_objects;
    close c;
    e := DBMS_UTILITY.GET_TIME;

    dbms_output.put_line(e - s);
end;
/

-- 8

GET_PARAMETER_VALUE

지정된 초기 파라미터의 값을 구하는 함수이다.

GET_PARAMETER_VALUE 함수의 세부 내용은 다음과 같다.

프로토타입

DBMS_UTILITY.GET_PARAMETER_VALUE
(
        parnam          IN            VARCHAR2,
        intval          IN OUT        BINARY_INTEGER,
        strval          IN OUT        VARCHAR2
) 
RETURN BINARY_INTEGER;

파라미터

파라미터

설명

parnam

값을 얻고자 하는 파라미터 이름

intval

integer 파라미터의 값 혹은 string 파라미터의 길이 값

strval

string 파라미터의 값

예제

set serveroutput on;

DECLARE
  parnam VARCHAR2(256);
  intval BINARY_INTEGER;
  strval VARCHAR2(256);
  partyp BINARY_INTEGER;
BEGIN
  partyp := dbms_utility.get_parameter_value('MAX_SESSION_COUNT',
                                              intval, strval);
  dbms_output.put('parameter value is: ');
  IF partyp = 1 THEN
    dbms_output.put_line(strval);
  ELSE
    dbms_output.put_line(intval);
  END IF;
  IF partyp = 1 THEN
    dbms_output.put('parameter value length is: ');
    dbms_output.put_line(intval);
  END IF;
  dbms_output.put('parameter type is: ');
  IF partyp = 1 THEN
    dbms_output.put_line('string');
  ELSE
    dbms_output.put_line('integer');
  END IF;
END;
/

-- parameter value is: 20
-- parameter type is: integer

TABLE_TO_COMMA

테이블 이름들을 구성 요소로 하는 인덱스 테이블을 분석하여 테이블 이름들이 쉼표로 구분되어 나열된문자열로 변환하는 프러시저입니다.

TABLE_TO_ COMMA 프러시저의 세부 내용은 다음과 같습니다.

프로토타입

DBMS_UTILITY.TABLE_TO_COMMA
(
    tab          IN       UNCL_ARRAY,
    tablen       OUT      BINARY_INTEGER,
    list         OUT      VARCHAR2
);

DBMS_UTILITY.TABLE_TO_COMMA
(
    tab          IN       LNAME_ARRAY,
    tablen       OUT      BINARY_INTEGER,
    list         OUT      VARCHAR2
);

파라미터

파라미터

설명

tab

테이블 이름들을 구성 요소로 갖는 인덱스 테이블
uncl_array와 lname_array를 입력 값으로 받을 수 있음

tablen

생성되는 이름들의 개수
이때 tab에 변수를 자체적으로 할당할 경우 변수를 할당한 부분의 앞 부분이 비어있더라도 NULL값이 할당된것으로 간주하여 tablen에 값을 부여
예를 들어 tab(3) := 'a';를 통해 테이블의 3번째 값에 a를 할당한 경우 tab(1)과 tab(2)가 비어있어도 NULL 값이 할당된 것으로 간주하여 tablen의 결과는 3 이 됨

list

콤마로 구분되어 있는 테이블 이름들의 목록 문자열
이때 tab에 변수를 자체적으로 할당할 경우, 변수를 할당한 부분의 앞 부분이 비어있더라도 NULL값이 할당된것으로 간주하여 list에 값을 부여
예를 들어 tab(3) := 'a';를 통해 테이블의 3번째 값에 a를 할당한 경우 tab(1)과 tab(2) 가 비어있어도 NULL 값이 할당된 것으로 간주하여 list의 결과는 ',,a'가 됨

예제

set serveroutput on;

declare
    tab dbms_utility.uncl_array;
    tablen binary_integer;
    str varchar2(1000);
begin
    tab(3) := 'a';
    dbms_utility.table_to_comma(tab, tablen, str);

    dbms_output.put_line(str);
    dbms_output.put_line(tablen);
end;
/

-- ,,a
-- 3

PreviousDBMS_TYPES NextDBMS_VERIFY

Last updated 17 days ago

hashtag개요

hashtag타입

hashtagUNCL_ARRAY

hashtagLNAME_ARRAY

hashtagMAXNAME_ARRAY

hashtag프러시저와 함수

hashtagCOMMA_TO_TABLE

hashtagCURRENT_INSTANCE

hashtagCOMPLIE_SCHEMA

hashtagEXEC_DDL_STATEMENT

hashtagFORMAT_CALL_STACK

hashtagFORMAT_ERROR_BACKTRACE

hashtagFORMAT_ERROR_STACK

hashtagFORMAT_VM_MM

hashtagGET_HASH_VALUE

hashtagGET_TIME

hashtagGET_PARAMETER_VALUE

hashtagTABLE_TO_COMMA

개요

타입

UNCL_ARRAY

LNAME_ARRAY

MAXNAME_ARRAY

프러시저와 함수

COMMA_TO_TABLE

CURRENT_INSTANCE

COMPLIE_SCHEMA

EXEC_DDL_STATEMENT

FORMAT_CALL_STACK

FORMAT_ERROR_BACKTRACE

FORMAT_ERROR_STACK

FORMAT_VM_MM

GET_HASH_VALUE

GET_TIME

GET_PARAMETER_VALUE

TABLE_TO_COMMA