OWA_UTIL

OWA_UTIL 패키지의 기본 개념과 패키지 내의 프러시저를 사용하는 방법을 설명합니다.

개요

OWA_UTIL은 웹 에이전트에서 주로 사용할 유틸리티를 담고 있는 패키지입니다.

서브프로그램

본 절에서는 OWA_UTIL 패키지에서 제공하는 서브프로그램을 알파벳 순으로 설명합니다.

GET_CGI_ENV

지정한 CGI 환경 변수의 값을 반환합니다.

프로토타입

FUNCTION GET_CGI_ENV
(
    param          IN       VARCHAR2
)
RETURN VARCHAR2;

• 파라미터

파라미터	설명
param	CGI 환경 변수의 이름 대소문자를 구별하지 않음

• 반환값

지정한 CGI 환경 변수의 값입니다. 변수가 정의되지 않은 경우 또는 웹 게이트웨이 환경이 아닌 경우 NULL을 반환합니다.

GET_OWA_SERVICE_PATH

요청을 처리하는 PL/SQL 게이트웨이의 전체 가상 경로를 반환합니다.

• 프로토타입

FUNCTION GET_OWA_SERVICE_PATH
RETURN VARCHAR2;

• 반환값

요청을 처리하는 PL/SQL 게이트웨이의 가상 경로입니다. 웹 게이트웨이 환경이 아닌 경우 NULL을 반환합니다.

GET_PROCEDURE

PL/SQL 게이트웨이에 의해 호출되는 프로시저의 이름을 반환합니다.

• 프로토타입

FUNCTION GET_PROCEDURE
RETURN VARCHAR2;

• 반환값

프로시저가 패키지에 정의된 경우 패키지 이름을 포함한 프로시저 이름입니다. 웹 게이트웨이 환경이 아닌 경우 NULL을 반환합니다.

HTTP_HEADER_CLOSE

HTTP 헤더를 닫기 위해 개행 문자를 생성합니다.

• 프로토타입

PROCEDURE HTTP_HEADER_CLOSE;

• 사용 노트

MIME_HEADER, REDIRECT_URL, STATUS_LINE 프러시저의 CLOSE_FLAG 파라미터를 사용하여 헤더를 닫지 않은 경우 이 프러시저를 사용합니다. HTTP 헤더는 HTP.PRINT 또는 HTP.PRN 호출 전에 닫아야 합니다.

MIME_HEADER

스크립트가 반환하는 기본 MIME 헤더를 변경합니다.

• 프로토타입

PROCEDURE MIME_HEADER
(
    mime_type      IN       VARCHAR2   DEFAULT NULL,
    close_flag     IN       BOOLEAN    DEFAULT TRUE,
    char_set       IN       VARCHAR2   DEFAULT NULL
);

• 파라미터

파라미터	설명
mime_type	생성할 MIME 타입 NULL인 경우 기본값으로 'text/html'이 사용됨
close_flag	HTTP 헤더를 닫을지 여부 TRUE이면 두 개의 개행 문자를 전송하여 HTTP 헤더를 닫음 그렇지 않으면 한 개의 개행 문자를 전송하고 HTTP 헤더는 열린 상태로 유지됨
char_set	사용할 문자 집합 문자 집합은 MIME 타입이 'text' 타입인 경우에만 의미가 있음 MIME 타입이 'text'가 아닌 경우(예: 'image') 문자 집합은 무시됨

• 사용 노트

이 프러시저는 HTP.PRINT 또는 HTP.PRN 호출 전에 사용해야 합니다. char_set 파라미터가 NULL이고 MIME 타입이 'text'로 시작하는 경우, REQUEST_IANA_CHARSET 환경 변수에서 문자 집합을 자동으로 가져옵니다.

MIME 타입이 'text'인 경우 다음 형식으로 헤더를 생성합니다:

Content-type: text/plain; charset=ISO-8859-4

• 예제

BEGIN
    owa_util.mime_header('text/plain', FALSE, 'ISO-8859-4');
    htp.print('Hello, World!');
END;
/

PRINT_CGI_ENV

PL/SQL 게이트웨이에서 저장 프로시저에 제공하는 모든 CGI 환경 변수와 그 값을 생성합니다.

• 프로토타입

PROCEDURE PRINT_CGI_ENV;

• 사용 노트

이 프러시저는 다음 형식으로 목록을 생성합니다.

cgi_env_var_name = value

웹 게이트웨이 환경이 아닌 경우 아무것도 출력하지 않습니다.

REDIRECT_URL

애플리케이션 서버가 지정한 URL을 방문하도록 지정합니다.

• 프로토타입

PROCEDURE REDIRECT_URL
(
    target_url     IN       VARCHAR2,
    close_flag     IN       BOOLEAN    DEFAULT TRUE
);

• 파라미터

파라미터	설명
target_url	방문할 URL URL은 반환할 웹 페이지 또는 실행할 프로그램을 지정할 수 있ㅇ
close_flag	HTTP 헤더를 닫을지 여부 TRUE이면 두 개의 개행 문자를 전송하여 HTTP 헤더를 닫음 그렇지 않으면 한 개의 개행 문자를 전송하고 HTTP 헤더는 열린 상태로 유지됨

• 사용 노트

이 프러시저는 HTP 프러시저 또는 HTF 함수 호출 전에 사용해야 합니다.

이 프러시저는 다음 형식의 헤더를 생성합니다.

Location: <target_url>

• 예제

BEGIN
    owa_util.redirect_url('http://www.example.com/newpage.html');
END;
/

STATUS_LINE

표준 HTTP 상태 코드를 클라이언트에 전송합니다.

• 프로토타입

PROCEDURE STATUS_LINE
(
    status         IN       NUMBER,
    reason         IN       VARCHAR2   DEFAULT NULL,
    close_flag     IN       BOOLEAN    DEFAULT TRUE
);

• 파라미터

파라미터	설명
status	상태 코드
reason	상태 코드를 설명하는 문자열
close_flag	HTTP 헤더를 닫을지 여부 TRUE이면 두 개의 개행 문자를 전송하여 HTTP 헤더를 닫음 그렇지 않으면 한 개의 개행 문자를 전송하고 HTTP 헤더는 열린 상태로 유지됨

• 사용 노트

이 프러시저는 HTP.PRINT 또는 HTP.PRN 호출 전에 사용해야 상태 코드가 "콘텐츠 데이터"가 아닌 헤더의 일부로 반환됩니다. 이 프러시저는 다음 형식의 헤더를 생성합니다.

Status: <status> <reason>

• 예제

BEGIN
    owa_util.status_line(404, 'Not Found');
    htp.print('The requested page was not found.');
END;
/

WHO_CALLED_ME

어떤 오브젝트로부터 본 오브젝트가 호출되었는지 정보를 가져옵니다.

• 프로토타입

PROCEDURE WHO_CALLED_ME 
(
    owner          OUT      VARCHAR2,
    name           OUT      VARCHAR2,
    lineno         OUT      NUMBER,
    caller_t       OUT      VARCHAR2
);

• 파라미터

파라미터	설명
owner	해당 오브젝트를 호출한 오브젝트의 소유자
name	해당 오브젝트를 호출한 오브젝트의 이름
lineno	해당 오브젝트를 호출한 오브젝트의 라인번호
caller_t	해당 오브젝트를 호출한 오브젝트의 타입

• 예제

create or replace procedure OWA_PROC1 
as
    v1 varchar(128);
    v2 varchar(128);
    v3 number;
    v4 varchar(128);
begin 
    owa_util.who_called_me (v1, v2, v3, v4);

    dbms_output.put_line (v1); 
    dbms_output.put_line (v2); 
    dbms_output.put_line (v3); 
    dbms_output.put_line (v4); 
end;
/

create or replace procedure OWA_PROC2 
as
begin 
    OWA_PROC1;
end;
/

begin
    OWA_PROC1; 
end;
/

2
ANONYMOUS BLOCK 

begin
    OWA_PROC2;
end;
/

TIBERO
OWA_PROC2
4
PROCEDURE