DBMS_XMLDOM

DBMS_XMLDOM 패키지의 기본 개념과 패키지 내의 프러시저와 함수를 사용하는 방법을 설명합니다. DBMS_XMLDOM 패키지는 Solaris x86에서는 지원되지 않습니다.

개요

DBMS_XMLDOM은 XML 문서 처리를 위한 DOM API를 제공합니다. 다음은 DBMS_XMLDOM 패키지 내에 정의된 상수입니다.

ELEMENT_NODE CONSTANT PLS_INTEGER := 1;
ATTRIBUTE_NODE CONSTANT PLS_INTEGER := 2;
TEXT_NODE CONSTANT PLS_INTEGER := 3;
CDATA_SECTION_NODE CONSTANT PLS_INTEGER := 4;
ENTITY_REFERENCE_NODE CONSTANT PLS_INTEGER := 5;
ENTITY_NODE CONSTANT PLS_INTEGER := 6;
PROCESSING_INSTRUCTION_NODE CONSTANT PLS_INTEGER := 7;
COMMENT_NODE CONSTANT PLS_INTEGER := 8;
DOCUMENT_NODE CONSTANT PLS_INTEGER := 9;
DOCUMENT_TYPE_NODE CONSTANT PLS_INTEGER := 10;
DOCUMENT_FRAGMENT_NODE CONSTANT PLS_INTEGER := 11;
NOTATION_NODE CONSTANT PLS_INTEGER := 12;

타입

본 절에서는 DBMS_XMLDOM 패키지에서 제공하는 별도 정의된 타입들을 알파벳 순으로 설명합니다.

DOMAttr

RAW 타입으로 이루어진 ID를 가진 RECORD 타입입니다. DOM에서 Attribute를 의미합니다.

DOMAttr 타입의 세부 내용은 다음과 같습니다.

• 프로토타입

TYPE DOMAttr IS RECORD(id RAW(16));

DOMCDataSection

RAW 타입으로 이루어진 ID를 가진 RECORD 타입입니다. DOM에서 CDataSection을 의미합니다.

DOMCDataSection 타입의 세부 내용은 다음과 같습니다.

• 프로토타입

TYPE DOMCDataSection IS RECORD(id RAW(16));

DOMCharacterData

RAW 타입으로 이루어진 ID를 가진 RECORD 타입입니다. DOM에서 CharacterData를 의미합니다.

DOMCharacterData 타입의 세부 내용은 다음과 같습니다.

• 프로토타입

TYPE DOMCharacterData IS RECORD(id RAW(16));

DOMComment

RAW 타입으로 이루어진 ID를 가진 RECORD 타입입니다. DOM에서 Comment를 의미합니다.

DOMComment 타입의 세부 내용은 다음과 같습니다.

• 프로토타입

TYPE DOMComment IS RECORD(id RAW(16));

DOMDocument

RAW 타입으로 이루어진 ID를 가진 RECORD 타입입니다. DOM에서 Document를 의미합니다.

DOMDocument 타입의 세부 내용은 다음과 같습니다.

• 프로토타입

TYPE DOMDocument IS RECORD(id RAW(16));

DOMDocumentFragment

RAW 타입으로 이루어진 ID를 가진 RECORD 타입입니다. DOM에서 DocumentFragment를 의미합니다.

DOMDocumentFragment 타입의 세부 내용은 다음과 같습니다.

• 프로토타입

TYPE DOMDocumentFragment IS RECORD(id RAW(16));

DOMDocumentType

RAW 타입으로 이루어진 ID를 가진 RECORD 타입입니다. DOM에서 DocumentType을 의미합니다.

DOMDocumentType 타입의 세부 내용은 다음과 같습니다.

• 프로토타입

TYPE DOMDocumentType IS RECORD(id RAW(16));

DOMElement

RAW 타입으로 이루어진 ID를 가진 RECORD 타입입니다. DOM에서 Element를 의미합니다.

DOMElement 타입의 세부 내용은 다음과 같습니다.

• 프로토타입

TYPE DOMElement IS RECORD(id RAW(16));

DOMEntity

RAW 타입으로 이루어진 ID를 가진 RECORD 타입입니다. DOM에서 Entity를 의미합니다.

DOMEntity 타입의 세부 내용은 다음과 같습니다.

• 프로토타입

TYPE DOMEntity IS RECORD(id RAW(16));

DOMEntityReference

RAW 타입으로 이루어진 ID를 가진 RECORD 타입입니다. DOM에서 EntityReference를 의미합니다.

DOMEntityReference 타입의 세부 내용은 다음과 같습니다.

• 프로토타입

TYPE DOMEntityReference IS RECORD(id RAW(16));

DOMImplementation

RAW 타입으로 이루어진 ID를 가진 RECORD 타입입니다. DOM에서 Implementation을 의미합니다.

DOMImplementation 타입의 세부 내용은 다음과 같습니다.

• 프로토타입

TYPE DOMImplementation IS RECORD(id RAW(16));

DOMNamedNodeMap

RAW 타입으로 이루어진 ID를 가진 RECORD 타입입니다. DOM에서 NamedNodeMap을 의미합니다.

DOMNamedNodeMap 타입의 세부 내용은 다음과 같습니다.

• 프로토타입

TYPE DOMNamedNodeMap IS RECORD(id RAW(16));

DOMNode

RAW 타입으로 이루어진 ID를 가진 RECORD 타입입니다. DOM에서 노드를 의미합니다.

DOMNode 타입의 세부 내용은 다음과 같습니다.

• 프로토타입

TYPE DOMNode IS RECORD(id RAW(16));

DOMNodeList

RAW 타입으로 이루어진 ID를 가진 RECORD 타입입니다. DOM에서 NodeList를 의미합니다.

DOMNodeList 타입의 세부 내용은 다음과 같습니다.

• 프로토타입

TYPE DOMNodeList IS RECORD(id RAW(16));

DOMNotation

RAW 타입으로 이루어진 ID를 가진 RECORD 타입입니다. DOM에서 Notation을 의미합니다.

DOMNotation 타입의 세부 내용은 다음과 같습니다.

• 프로토타입

TYPE DOMNotation IS RECORD(id RAW(16));

DOMProcessingInstruction

RAW 타입으로 이루어진 ID를 가진 RECORD 타입입니다. DOM에서 ProcessingInstruction을 의미합니다.

DOMProcessingInstruction 타입의 세부 내용은 다음과 같습니다.

• 프로토타입

TYPE DOMProcessingInstruction IS RECORD(id RAW(16));

DOMText

RAW 타입으로 이루어진 ID를 가진 RECORD 타입입니다. DOM에서 Text를 의미합니다.

DOMText 타입의 세부 내용은 다음과 같습니다.

• 프로토타입

TYPE DOMText IS RECORD(id RAW(16));

프러시저와 함수

본 절에서는 DBMS_XMLDOM 패키지에서 제공하는 프러시저와 함수를 알파벳 순으로 설명합니다.

ADOPTNODE

선택된 노드를 Document에 추가합니다. 본래 있던 Document에서는 해당 노드가 제거되고, 새로운 노드를 출력합니다.

ADOPTNODE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.ADOPTNODE
(
    doc              IN       DOMDocument,
    importedNode     IN       DOMNode
)
RETURN DOMNode;

• 파라미터

파라미터	설명
doc	노드가 추가될 Document
importedNode	Document에 추가될 노드

• 예제

declare
    doc dbms_xmldom.DOMDocument;
    new_doc dbms_xmldom.DOMDocument;
    ele dbms_xmldom.DOMElement;
    docNode dbms_xmldom.DOMNode;
    n dbms_xmldom.DOMNode;
    n_ele dbms_xmldom.DOMNode;
begin
    doc := dbms_xmldom.newDomDocument;
    new_doc := dbms_xmldom.newDomDocument;
    docNode := dbms_xmldom.makeNode(doc);
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    n_ele := dbms_xmldom.makeNode(ele);
    n := dbms_xmldom.appendChild(docNode, n_ele);
    n := dbms_xmldom.adoptNode(new_doc, n_ele);
    dbms_xmldom.freeDocument(doc);
    dbms_xmldom.freeDocument(new_doc);
end;
/

APPENDCHILD

선택된 노드에 자식 노드를 추가하는 함수로 추가된 자식 노드를 출력합니다.

APPENDCHILD 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.APPENDCHILD
(
    n           IN      DOMNode, 
    newchild    IN      DOMNode  
)
RETURN DOMNode;

• 파라미터

파라미터	설명
n	자식 노드가 추가될 노드.
newchild	노드에 추가될 자식 노드.

• 예제

declare
    doc dbms_xmldom.DOMDocument;
    ele dbms_xmldom.DOMElement;
    docNode dbms_xmldom.DOMNode;
    n dbms_xmldom.DOMNode;
begin
    doc := dbms_xmldom.newDomDocument;
    docNode := dbms_xmldom.makeNode(doc);
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    n := dbms_xmldom.makeNode(ele);
    n := dbms_xmldom.appendChild(docNode, n);
    dbms_xmldom.freeDocument(doc);
end;
/

APPENDDATA

DOMCharacterData 끝에 문자열을 연장합니다.

APPENDDATA 프러시저의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.APPENDDATA
(
    cd      IN    DOMCharacterData,
    arg     IN    VARCHAR2
);

• 파라미터

파라미터	설명
cd	DOMCharacterData
arg	DOMCharacterData에 추가할 값

• 예제

declare
    doc    dbms_xmldom.DOMDocument;
    txt    dbms_xmldom.DOMText;
    cd     dbms_xmldom.DOMCharacterData;
begin
    doc := dbms_xmldom.newDomDocument;
    txt := dbms_xmldom.createTextNode(doc, 'textnode');
    cd := dbms_xmldom.makeCharacterData(dbms_xmldom.makeNode(txt));
    dbms_xmldom.appendData(cd, '_appending');
    dbms_xmldom.freeDocument(doc);
end;
/

CLONENODE

DOMNode를 복사합니다. 복사한 DOMNode는 부모 노드가 존재하지 않습니다.

CLONENODE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.CLONENODE
(
    n        IN      DOMNode,
    deep     IN      BOOLEAN
)
RETURN DOMNode;

• 파라미터

파라미터	설명
n	DOMNode
deep	자식 노드를 복사할지 결정

• 예제

declare
    doc dbms_xmldom.DOMDocument;
    ele dbms_xmldom.DOMElement;
    n dbms_xmldom.DOMNode;
    cloneNode dbms_xmldom.DOMNode;
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc,'test');
    n := dbms_xmldom.makeNode(ele);
    cloneNode := dbms_xmldom.cloneNode(n, false);
    dbms_xmldom.freeDocument(doc);
end;
/

CREATEATTRIBUTE

해당 문서 안에 DOMAttr을 생성하는 함수입니다.

CREATEATTRIBUTE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.CREATEATTRIBUTE
(
    doc     IN     DOMDocument, 
    name    IN     VARCHAR2     
)
RETURN DOMAttr;

DBMS_XMLDOM.CREATEATTRIBUTE
(
    doc     IN     DOMDocument, 
    name    IN     VARCHAR2
    ns      IN     VARCHAR2
)
RETURN DOMAttr;

• 파라미터

파라미터	설명
doc	DOMAttr이 생성될 문서
name	새로운 DOMAttr의 qualified name
ns	새로운 DOMAttr의 네임스페이스

• 예제

declare
    doc     dbms_xmldom.DOMDocument;
    attr    dbms_xmldom.DOMAttr;
begin
    doc := dbms_xmldom.newDomDocument;
    attr := dbms_xmldom.createAttribute(doc, 'test');
    dbms_xmldom.freeDocument(doc);
end;
/

CREATECDATASECTION

해당 문서 안에 CDataSection을 생성하는 함수입니다.

CREATECDATASECTION 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.CREATECDATASECTION
(
    doc      IN     DOMDocument, 
    data     IN     VARCHAR2     
)
RETURN DOMCDataSection;

• 파라미터

파라미터	설명
doc	CDataSection이 생성될 문서
data	CDataSection에 들어갈 내용

• 예제

declare
    doc     dbms_xmldom.DOMDocument;
    cd      dbms_xmldom.DOMCDataSection;
begin
    doc := dbms_xmldom.newDomDocument;
    cd := dbms_xmldom.createCDataSection(doc, 'contents of cdatasection');
    dbms_xmldom.freeDocument(doc);
end;
/

CREATECOMMENT

해당 문서 안에 COMMENT를 생성하는 함수입니다.

CREATECOMMENT 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.CREATECOMMENT
(
    doc      IN     DOMDocument, 
    data     IN     VARCHAR2     
)
RETURN DOMComment;

• 파라미터

파라미터	설명
doc	COMMENT가 생성될 문서
data	COMMENT에 들어갈 내용

• 예제

declare
    doc     dbms_xmldom.DOMDocument;
    cd      dbms_xmldom.DOMComment;
begin
    doc := dbms_xmldom.newDomDocument;
    cm := dbms_xmldom.createComment(doc, 'comment!!');
    dbms_xmldom.freeDocument(doc);
end;
/

CREATEDOCUMENT

해당 문서 안에 DOMDocument를 생성하는 함수입니다.

CREATEDOCUMENT 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.CREATEDOCUMENT
(
    namespaceURI      IN         VARCHAR2,
    qualifiedName     IN         VARCHAR2,
    doctype           IN         DOMTYPE := NULL
)
RETURN DOMDocument;

• 파라미터

파라미터	설명
namespaceURI	DOMDocument의 네임스페이스 URI
qualifiedName	루트 엘리먼트의 이름
doctype	문서의 타입

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
begin
    doc := dbms_xmldom.createDocument('xmlns="http://www.w3.org/1999"', 'QName');
    dbms_xmldom.freeDocument(doc);
end;
/

CREATEDOCUMENTFRAGMENT

해당 문서 안에 DOMDocumentFragment를 생성하는 함수입니다.

CREATEDOCUMENTFRAGMENT 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.CREATEDOCUMENTFRAGMENT
(
    doc    IN    DOMDocument,
)
RETURN DOMDocumentFragment;

• 파라미터

파라미터	설명
doc	Element가 생성될 문서

• 예제

declare
    doc        dbms_xmldom.DOMDocument;
    docFrg     dbms_xmldom.DOMDocumentFragment;
begin
    doc := dbms_xmldom.newDomDocument;
    docFrg := dbms_xmldom.createDocumentFragment(doc);
    dbms_xmldom.freeDocument(doc);
end;
/

CREATEELEMENT

해당 문서 안에 Element를 생성하는 함수입니다.

CREATEELEMENT 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.CREATEELEMENT
(
    doc      IN    DOMDocument,
    tagname  IN    VARCHAR2     
)
RETURN DOMElement;

DBMS_XMLDOM.CREATEELEMENT
(
    doc      IN    DOMDocument,
    tagname  IN    VARCHAR2  
    ns       IN    VARCHAR2     
)
RETURN DOMElement;

• 파라미터

파라미터	설명
doc	Element가 생성될 문서
tagname	Element의 태그 이름
ns	Element의 네임스페이스

• 예제

declare
    doc     dbms_xmldom.DOMDocument;
    ele     dbms_xmldom.DOMElement;
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'root');
    dbms_xmldom.freeDocument(doc);
end;
/

CREATEENTITYREFERENCE

해당 문서 안에 DOMEntityReference를 생성하는 함수입니다.

CREATEENTITYREFERENCE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.CREATEENTITYREFERENCE
(
    doc      IN    DOMDocument,
    name     IN    VARCHAR2     
)
RETURN DOMEntityReference;

• 파라미터

파라미터	설명
doc	DOMEntityReference가 생성될 문서

• 예제

declare
    doc     dbms_xmldom.DOMDocument;
    etr     dbms_xmldom.DOMEntityReference;
begin
    doc := dbms_xmldom.newDomDocument;
    etr := dbms_xmldom.createEntityReference(doc, 'entity');
    dbms_xmldom.freeDocument(doc);
end;
/

CREATEPROCESSINGINSTRUCTION

해당 문서 안에 DOMProcessingInstruction를 생성하는 함수입니다.

CREATEPROCESSINGINSTRUCTION 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.CREATEPROCESSINGINSTRUCTION
(
    doc      IN    DOMDocument,
    target   IN    VARCHAR2  
    data     IN    VARCHAR2     
)
RETURN DOMEntityReference;

• 파라미터

파라미터	설명
doc	DOMProcessingInstruction이 생성될 문서
target	ProcessingInstruction의 타깃
data	ProcessingInstruction의 데이터

• 예제

declare
    doc    dbms_xmldom.DOMDocument;
    pi     dbms_xmldom.DOMProcessingInstruction;
begin
    doc := dbms_xmldom.newDomDocument;
    pi := dbms_xmldom.createProcessingInstruction(doc, 'target', 'data');
    dbms_xmldom.freeDocument(doc);
end;
/

CREATETEXTNODE

해당 문서 안에 Text를 생성하는 함수입니다.

CREATETEXTNODE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.CREATETEXTNODE
(
    doc      IN    DOMDocument,
    name     IN    VARCHAR2     
)
RETURN DOMText;

• 파라미터

파라미터	설명
doc	Text가 생성될 문서
data	Text에 들어갈 내용

• 예제

declare
    doc     dbms_xmldom.DOMDocument;
    txt     dbms_xmldom.DOMText;
begin
    doc := dbms_xmldom.newDomDocument;
    txt := dbms_xmldom.createTextNode(doc, 'text');
    dbms_xmldom.freeDocument(doc);
end;
/

DELETEDATA

DOMCharacterData의 특정 오프셋에 데이터를 지웁니다.

DELETEDATA 프러시저의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.DELETEDATA
(
    cd        IN    DOMCharacterData,
    offset    IN    number,
    cnt       IN    number     
)

• 파라미터

파라미터	설명
cd	DOMCharacterData
offset	지워질 데이터의 오프셋
cnt	지워질 문자 데이터의 개수

• 예제

declare
    doc     dbms_xmldom.DOMDocument;
    txt     dbms_xmldom.DOMText;
    cd      dbms_xmldom.DOMCharacterData;
begin
    doc := dbms_xmldom.newDomDocument;
    txt := dbms_xmldom.createTextNode(doc, 'textnode');
    cd := dbms_xmldom.makeCharacterData(dbms_xmldom.makenode(txt));
    dbms_xmldom.deleteData(cd, 4, 4);
    dbms_xmldom.freeDocument(doc);
end;
/

FREEDOCFRAG

DOMDocumentFragment Type을 초기화해 주는 프러시저입니다.

FREEDOCFRAG 프러시저의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.FREEDOCFRAG
(
    doc        IN    DOMDocumentFragment
);

• 파라미터

파라미터	설명
doc	초기화해 줄 DocumentFragment

FREEDOCUMENT

Document에 관련된 리소스들을 해제하는 프러시저입니다.

FREEDOCUMENT 프러시저의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.FREEDOCUMENT
(
    doc     IN    DOMDocument
);

• 파라미터

파라미터	설명
doc	Resource를 해제할 문서

• 예제

declare
    doc    dbms_xmldom.DOMDocument;
begin
    doc := dbms_xmldom.newDomDocument;
    dbms_xmldom.freedocument(doc);
end;
/

FREENODE

DOMNode에 관련된 리소스들을 해제하는 프러시저입니다. DOMNode가 문서인 경우에 DOMNode 타입을 초기화하고 해당 문서와 관련된 리소스를 해제합니다. 문서가 아닌 경우에는 해당 DOMNode 타입만 초기화 해줍니다.

FREENODE 프러시저의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.FREENODE
(
    n     IN    DOMNode
);

• 파라미터

파라미터	설명
n	리소스를 해제할 노드

• 예제

declare
    doc     dbms_xmldom.DOMDocument;
begin
    doc := dbms_xmldom.newDomDocument;
    dbms_xmldom.freenode(dbms_xmldom.makeNode(doc));
    dbms_xmldom.freeDocument(doc);
end;
/

GETATTRIBUTE

특정 Element로부터 Attribute의 값을 가져오는 함수입니다.

GETATTRIBUTE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETATTRIBUTE
(
    elem     IN    DOMElement,
    name     IN    VARCHAR2
);
RETURN VARCHAR2;

DBMS_XMLDOM.GETATTRIBUTE
(
    elem     IN    DOMElement,
    name     IN    VARCHAR2
    ns       IN    VARCHAR2
);
RETURN VARCHAR2;

• 파라미터

파라미터	설명
elem	해당 Attribute를 찾을 Element
name	Attribute의 이름
ns	Attribute의 네임스페이스

• 예제

declare
    doc           dbms_xmldom.DOMDocument;
    ele           dbms_xmldom.DOMElement;
    attr_val     VARCHAR2(20);
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    dbms_xmldom.setAttribute(ele, 'attr1', 'new_attribute');
    attr_val := dbms_xmldom.getAttribute(ele, 'attr1');
    dbms_output.put_line(attr_val);
    dbms_xmldom.freeDocument(doc);
end;
/

GETATTRIBUTENODE

Element로부터 특정 DOMAttr을 가져오는 함수입니다.

GETATTRIBUTENODE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETATTRIBUTENODE
(
    elem     IN    DOMElement,
    name     IN    VARCHAR2
)
RETURN DOMAttr;

DBMS_XMLDOM.GETATTRIBUTENODE
(
    elem     IN    DOMElement,
    name     IN    VARCHAR2
    ns       IN    VARCHAR2
)
RETURN DOMAttr;

• 파라미터

파라미터	설명
elem	해당 Attribute를 찾을 Element
name	Attribute의 이름
ns	Attribute의 네임스페이스

• 예제

declare
    doc     dbms_xmldom.DOMDocument;
    ele     dbms_xmldom.DOMElement;
    attr    dbms_xmldom.DOMAttr;
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    dbms_xmldom.setAttribute(ele, 'attr1', 'new_attribute');
    attr := dbms_xmldom.getAttributeNode(ele, 'attr1');
    dbms_xmldom.freeDocument(doc);
end;
/

GETATTRIBUTES

Element에 있는 모든 Attribute들을 출력하는 함수입니다.

GETATTRIBUTES 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETATTRIBUTES
(
    n     IN    DOMNode
)
RETURN DOMNamedNodeMap;

• 파라미터

파라미터	설명
n	DOMNode 형태의 Element가 와야함

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    n         dbms_xmldom.DOMNode;
    attr      dbms_xmldom.DOMAttr;
    nm        dbms_xmldom.DOMNamedNodeMap;
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    dbms_xmldom.setAttribute(ele, 'attr1', 'first_attribute');
    dbms_xmldom.setAttribute(ele, 'attr2', 'second_attribute');
    nm := dbms_xmldom.getAttributes(dbms_xmldom.makeNode(ele));
    dbms_xmldom.freeDocument(doc);
end;
/

GETCHILDNODES

해당 노드의 자식 노드들을 출력합니다.

GETCHILDNODES 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETCHILDNODES
(
    n     IN    DOMNode
)
RETURN DOMNodeList;

• 파라미터

파라미터	설명
n	자식 노드들을 출력할 부모 노드

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    docNode   dbms_xmldom.DOMNode;
    p         dbms_xmldom.DOMNode;
    n         dbms_xmldom.DOMNode;
    nl        dbms_xmldom.DOMNodeList;
begin
    doc := dbms_xmldom.newDomDocument;
    docNode := dbms_xmldom.makeNode(doc);
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    p := dbms_xmldom.appendChild(docNode, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child1');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child2');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child3');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    nl := dbms_xmldom.getChildNodes(p);
    dbms_xmldom.freeDocument(doc);
end;
/

GETCHILDRENBYTAGNAME

특정 태그명을 갖는 Element들을 자식 노드들에서 찾아서 출력해주는 함수입니다.

GETCHILDRENBYTAGNAME 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETCHILDRENBYTAGNAME
(
    elem     IN    DOMElement,
    name     IN    VARCHAR2
)
RETURN DOMNodeList;

DBMS_XMLDOM.GETCHILDRENBYTAGNAME
(
    elem     IN    DOMElement,
    name     IN    VARCHAR2,
    ns       IN    VARCHAR2
)
RETURN DOMNodeList;

• 파라미터

파라미터	설명
elem	자식 노드들을 출력할 Parent Element 노드.
name	찾을 노도들의 태그명
ns	찾을 노드들의 네임스페이스

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    docNode   dbms_xmldom.DOMNode;
    p         dbms_xmldom.DOMNode;
    n         dbms_xmldom.DOMNode;
    nl        dbms_xmldom.DOMNodeList;
begin
    doc := dbms_xmldom.newDomDocument;
    docNode := dbms_xmldom.makeNode(doc);
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    p := dbms_xmldom.appendChild(docNode, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child1');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child1');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child3');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    nl := dbms_xmldom.getChildrenByTagName(ele, 'child1');
    dbms_xmldom.freeDocument(doc);
end;
/

GETDATA

DOMChataterData 데이터를 가져옵니다.

GETDATA 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETDATA
(
    cd     IN    DOMCharacterData
)
RETURN VARCHAR2;

• 파라미터

파라미터	설명
cd	데이터를 가져올 DOMCharacterData

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    txt       dbms_xmldom.DOMText;
    cd        dbms_xmldom.DOMCharacterData;
begin
    doc := dbms_xmldom.newDomDocument;
    txt := dbms_xmldom.createTextNode(doc, 'textnode');
    cd := dbms_xmldom.makeCharacterData(dbms_xmldom.makeNode(txt));
    dbms_output.put_line(dbms_xmldom.getData(cd));
    dbms_xmldom.freeDocument(doc);
end;
/

GETDOCUMENTELEMENT

문서의 root element를 가져옵니다.

GETDOCUMENTELEMENT 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETDOCUMENTELEMENT
(
    doc     IN    DOMDocument
)
RETURN DOMElement;

• 파라미터

파라미터	설명
doc	root element를 가져올 문서

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    n         dbms_xmldom.DOMNode;
begin
    doc := dbms_xmldom.newDomDocument(
           '<first><second></second></first>');
    ele := dbms_xmldom.getDocumentElement(doc);
    n := dbms_xmldom.makeNode(ele);
    dbms_output.put_line(dbms_xmldom.getNodeName(n));
    dbms_xmldom.freeDocument(doc);
end;
/

GETELEMENTSBYTAGNAME

특정 태그명을 갖는 Element들을 찾아서 출력해주는 함수입니다. GETELEMENTSBYTAGNAME 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETELEMENTSBYTAGNAME
(
    doc      IN    DOMDocument,
    name     IN    VARCHAR2
)
RETURN DOMNodeList;  

DBMS_XMLDOM.GETELEMENTSBYTAGNAME
(
    elem     IN    DOMDocument,
    name     IN    VARCHAR2
)
RETURN DOMNodeList;  

DBMS_XMLDOM.GETELEMENTSBYTAGNAME
(
    elem     IN    DOMDocument,
    name     IN    VARCHAR2,
    ns       IN    VARCHAR2
)
RETURN DOMNodeList;  

• 파라미터

파라미터	설명
doc	Element들을 찾을 Document 노드
elem	Element들을 찾을 Parent Element 노드
name	찾을 노도들의 태그명
ns	찾을 노드들의 네임스페이스

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    docNode   dbms_xmldom.DOMNode;
    p         dbms_xmldom.DOMNode;
    n         dbms_xmldom.DOMNode;
    nl        dbms_xmldom.DOMNodeList;
begin
    doc := dbms_xmldom.newDomDocument;
    docNode := dbms_xmldom.makeNode(doc);
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    p := dbms_xmldom.appendChild(docNode, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child1');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child1');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child3');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    nl := dbms_xmldom.getElementsByTagname(doc, 'child1');
    dbms_xmldom.freeDocument(doc);
end;
/

GETEXPANDEDNAME

확장된 이름을 가져오는 프러시저와 함수입니다.

GETEXPANDEDNAME 프러시저와 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETEXPANDEDNAME
(
    n        IN    DOMNode,
    data     IN    VARCHAR2
);

DBMS_XMLDOM.GETEXPANDEDNAME
(
    a        IN    DOMAttr
)
RETURN VARCHAR2;      

DBMS_XMLDOM.GETEXPANDEDNAME
(
    elem        IN    DOMElement
)
RETURN VARCHAR2;      

• 파라미터

파라미터	설명
n	DOMNode
data	확장된 이름을 가져올 노드의 이름
a	DOMAttr
elem	DOMElement

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'name', 'ns');
    dbms_output.put_line(dbms_xmldom.getExpandedName(ele));
    dbms_xmldom.freeDocument(doc);
end;
/

GETFIRSTCHILD

첫 번째에 있는 자식 노드를 출력하는 함수입니다.

GETFIRSTCHILD 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETFIRSTCHILD
(
    n        IN    DOMNode
)
RETURN DOMNode;

• 파라미터

파라미터	설명
n	자식을 찾을 부모 노드

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    docNode   dbms_xmldom.DOMNode;
    p         dbms_xmldom.DOMNode;
    n         dbms_xmldom.DOMNode;
begin
    doc := dbms_xmldom.newDomDocument;
    docNode := dbms_xmldom.makeNode(doc);
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    p := dbms_xmldom.appendChild(docNode, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child1');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child2');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child3');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    n := dbms_xmldom.getFirstChild(p);
    dbms_xmldom.freeDocument(doc);
end;
/

GETIMPLEMENTATION

문서의 DOMImplementation을 가져옵니다.

GETIMPLEMENTATION 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETIMPLEMENTATION
(
    doc        IN    DOMDocument
)
RETURN DOMImplementation;

• 파라미터

파라미터	설명
doc	DOMImplementation을 가져올 문서

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    impl      dbms_xmldom.DOMImplementation;
begin
    doc := dbms_xmldom.newDomDocument;
    impl := dbms_xmldom.getImplementation(doc);
    dbms_xmldom.freeDocument(doc);
end;
/

GETLASTCHILD

마지막에 있는 자식 노드를 출력하는 함수입니다.

GETLASTCHILD 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETLASTCHILD
(
    n       IN    DOMNode
)
RETURN DOMNode;

• 파라미터

파라미터	설명
n	자식을 찾을 부모 노드

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    docNode   dbms_xmldom.DOMNode;
    p         dbms_xmldom.DOMNode;
    n         dbms_xmldom.DOMNode;
begin
    doc := dbms_xmldom.newDomDocument;
    docNode := dbms_xmldom.makeNode(doc);
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    p := dbms_xmldom.appendChild(docNode, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child1');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child2');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child3');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    n := dbms_xmldom.getLastChild(p);
    dbms_xmldom.freeDocument(doc);
end;
/

GETLENGTH

길이를 출력하는 함수입니다. CharacterData의 경우에는 문자의 길이를 출력하고, DOMNamedNodeMap 또는 DOMNodeList인 경우에는 개수를 출력합니다.

GETLENGTH 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETLENGTH
(
    cd       IN    DOMCharacterData
)
RETURN NUMBER;

DBMS_XMLDOM.GETLENGTH
(
    nnm       IN    DOMNamedNodeMap
)
RETURN NUMBER;

DBMS_XMLDOM.GETLENGTH
(
    nl       IN    DOMNodeList
)
RETURN NUMBER;

• 파라미터

파라미터	설명
cd	CharacterData를 가지고 있는 노드
nnm	여러 노드 정보를 맵 형태로 가지고 있는 타입
nl	여러 노드 정보를 List 형태로 가지고 있는 타입

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    docNode   dbms_xmldom.DOMNode;
    p         dbms_xmldom.DOMNode;
    n         dbms_xmldom.DOMNode;
    nl        dbms_xmldom.DOMNodeList;
    len       Number;
begin
    doc := dbms_xmldom.newDomDocument;
    docNode := dbms_xmldom.makeNode(doc);
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    p := dbms_xmldom.appendChild(docNode, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child1');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child2');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child3');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    nl := dbms_xmldom.getElementsByTagname(doc, 'child1');
    len := dbms_xmldom.getLength(nl);
    dbms_xmldom.freeDocument(doc);
end;
/

GETLOCALNAME

DOMAttr와 DOMElement에서 로컬이름을 가져옵니다. DOMNode는 qualified 이름에서 로컬 이름을 가져옵니다.

GETLOCALNAME 프러시저와 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETLOCALNAME
(
    n          IN       DOMNode,
    data       out      VARCHAR2
)

DBMS_XMLDOM.GETLOCALNAME
(
    a          IN       DOMAttr
)
RETURN VARCHAR2;

DBMS_XMLDOM.GETLOCALNAME
(
    elem          IN       DOMElement
)
RETURN VARCHAR2;

• 파라미터

파라미터	설명
n	DOMNode
data	local 이름이 리턴
a	DOMAttr
elem	DOMElement

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'name', 'ns');
    dbms_output.put_line(dbms_xmldom.getlocalname(ele));
    dbms_xmldom.freeDocument(doc);
end;
/

GETNAME

해당 노드의 이름을 출력해주는 함수입니다.

GETNAME 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETNAME
(
    a          IN       DOMAttr
)
RETURN VARCHAR2;

DBMS_XMLDOM.GETNAME
(
    dt          IN       DOMDocumentType
)
RETURN VARCHAR2;

• 파라미터

파라미터	설명
a	이름을 가져올 Attribute 노드
dt	이름을 가져올 DOMDocumentType 노드

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    attr      dbms_xmldom.DOMAttr;
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    dbms_xmldom.setAttribute(ele, 'attr1', 'new_attribute');
    attr := dbms_xmldom.getAttributeNode(ele, 'attr1');
    dbms_output.put_line(dbms_xmldom.getName(attr));
    dbms_xmldom.freeDocument(doc);
end;
/

GETNAMEDITEM

DOMNamedNodeMap에서 특정 이름을 갖는 노드를 가져오는 함수입니다.

GETNAMEDITEM 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETNAMEDITEM
(
    nnm          IN       DOMNamedNodeMap,
    name         IN       VARCHAR2
)
RETURN DOMNode;

DBMS_XMLDOM.GETNAMEDITEM
(
    nnm          IN       DOMNamedNodeMap,
    name         IN       VARCHAR2,
    ns           IN       VARCHAR2
)
RETURN DOMNode;

• 파라미터

파라미터	설명
nnm	노드들을 맵 형태로 가지고 있는 DOMNamedNodeMap 타입
name	DOMNamedNodeMap에서 가져올 노드의 이름
ns	DOMNamedNodeMap에서 가져올 노드의 네임스페이스

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    n         dbms_xmldom.DOMNode;
    nm        dbms_xmldom.DOMNamedNodeMap;
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    dbms_xmldom.setAttribute(ele, 'attr1', 'first_attribute');
    dbms_xmldom.setAttribute(ele, 'attr2', 'second_attribute');
    nm := dbms_xmldom.getAttributes(dbms_xmldom.makeNode(ele));
    n := dbms_xmldom.getNamedItem(nm, 'attr1');
    dbms_xmldom.freeDocument(doc);
end;
/

GETNEXTSIBLING

다음 형제 노드를 가져오는 함수입니다.

GETNEXTSIBLING 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETNEXTSIBLING
(
    n           IN       DOMNode
)
RETURN DOMNode;

• 파라미터

파라미터	설명
n	DOMNode

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    n         dbms_xmldom.DOMNode;
    docNode   dbms_xmldom.DOMNode;
begin
    doc := dbms_xmldom.newDomDocument('<root><tag1></tag1><tag2></tag2></root>');
    docNode := dbms_xmldom.makeNode(doc);
    n := dbms_xmldom.getFirstChild(docNode);
    n := dbms_xmldom.getNextSibling(n);
    dbms_xmldom.freeDocument(doc);
end;
/

GETNODENAME

노드의 이름을 출력하는 함수입니다.

GETNODENAME 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETNODENAME
(
    n        IN       DOMNode
)
RETURN VARCHAR2;

• 파라미터

파라미터	설명
n	이름을 출력할 노드이다.

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    n         dbms_xmldom.DOMNode;
    nm        dbms_xmldom.DOMNamedNodeMap;
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    dbms_xmldom.setAttribute(ele, 'attr1', 'first_attribute');
    dbms_xmldom.setAttribute(ele, 'attr2', 'second_attribute');
    nm := dbms_xmldom.getAttributes(dbms_xmldom.makeNode(ele));
    n := dbms_xmldom.getNamedItem(nm, 'attr1');
    dbms_output.put_line(dbms_xmldom.getNodeName(n));
    dbms_xmldom.freeDocument(doc);
end;
/

GETNODETYPE

노드의 타입 정보를 DBMS_XMLDOM의 상수형태로 출력해주는 함수입니다.

GETNODETYPE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETNODETYPE
(
    n        IN       DOMNode
)
RETURN NUMBER;

• 파라미터

파라미터	설명
n	타입 정보를 출력할 노드

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'root');
    dbms_output.put_line(dbms_xmldom.getNodeType(dbms_xmldom.makeNode(doc)));
    dbms_output.put_line(dbms_xmldom.getNodeType(dbms_xmldom.makeNode(ele)));
    dbms_xmldom.freeDocument(doc);
end;
/

GETNODEVALUE

노드의 값을 출력해주는 함수입니다.

GETNODEVALUE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETNODEVALUE
(
    n        IN       DOMNode
)
RETURN VARCHAR2;

• 파라미터

파라미터	설명
n	값을 출력할 노드

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    txt       dbms_xmldom.DOMText;
    n         dbms_xmldom.DOMNode;
begin
    doc := dbms_xmldom.newDomDocument;
    txt := dbms_xmldom.createTextNode(doc, 'text');
    n := dbms_xmldom.makeNode(txt);
    dbms_output.put_line(dbms_xmldom.getNodeValue(n));
    dbms_xmldom.freeDocument(doc);
end;
/

GETOWNERDOCUMENT

해당 노드가 속해 있는 Document를 출력해주는 함수입니다.

GETOWNERDOCUMENT 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETOWNERDOCUMENT
(
    n        IN       DOMNode
)
RETURN DOMDocument;

• 파라미터

파라미터	설명
n	문서를 찾을 노드

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'root');
    doc := dbms_xmldom.getOwnerDocument(dbms_xmldom.makeNode(ele));
    dbms_xmldom.freeDocument(doc);
end;
/

GETPARENTNODE

해당 노드의 부모 노드를 출력해주는 함수입니다.

GETPARENTNODE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETPARENTNODE
(
    n        IN       DOMNode
)
RETURN DOMNode;

• 파라미터

파라미터	설명
n	부모를 찾을 노드

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    docNode   dbms_xmldom.DOMNode;
    p         dbms_xmldom.DOMNode;
    n         dbms_xmldom.DOMNode;
    n1        dbms_xmldom.DOMNode;
    n2        dbms_xmldom.DOMNode;
    n3        dbms_xmldom.DOMNode;
begin
    doc := dbms_xmldom.newDomDocument;
    docNode := dbms_xmldom.makeNode(doc);
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    p := dbms_xmldom.appendChild(docNode, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child1');
    n1 := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child2');
    n2 := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child3');
    n3 := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    n := dbms_xmldom.getParentNode(n1);
    dbms_xmldom.freeDocument(doc);
end;
/

GETQUALIFIEDNAME

Element 또는 Attribute의 qualified name을 반환하는 함수입니다.

GETQUALIFIEDNAME 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETQUALIFIEDNAME
(
    n        IN       DOMAttr
)
RETURN VARCHAR2;

DBMS_XMLDOM.GETQUALIFIEDNAME
(
    n        IN       DOMElement
)
RETURN VARCHAR2;

• 파라미터

파라미터	설명
n	Qualified name을 출력할 Attribute 노드 또는 Element 노드

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    docNode   dbms_xmldom.DOMNode;
    n         dbms_xmldom.DOMNode;
    ele       dbms_xmldom.DOMElement;
    attr      dbms_xmldom.DOMAttr;
    attr_val  VARCHAR2(20);
begin
    doc := dbms_xmldom.newDomDocument(
             '<ns:test xmlns:ns="URI">content</ns:test>');
    docNode := dbms_xmldom.makeNode(doc);
    n := dbms_xmldom.getFirstChild(docNode);
    ele := dbms_xmldom.makeElement(n);
    dbms_output.put('QName : ');
    dbms_output.put_line(dbms_xmldom.getqualifiedname(ele));
    dbms_xmldom.freeDocument(doc);
end;
/

GETVALUE

Attribute노드의 값을 출력해주는 함수입니다.

GETVALUE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETVALUE
(
    n        IN       DOMAttr
)
RETURN VARCHAR2;

• 파라미터

파라미터	설명
a	값을 출력할 Attribute 노드

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    attr      dbms_xmldom.DOMAttr;
    attr_val  VARCHAR2(20);
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    dbms_xmldom.setAttribute(ele, 'attr1', 'new_attribute');
    attr := dbms_xmldom.getAttributeNode(ele, 'attr1');
    attr_val := dbms_xmldom.getValue(attr);
    dbms_output.put_line(attr_val);
    dbms_xmldom.freeDocument(doc);
end;
/

GETXMLTYPE

문서를 XMLType 형태로 출력합니다.

GETXMLTYPE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.GETXMLTYPE
(
    doc        IN       DOMDocument
)
RETURN XMLType;

• 파라미터

파라미터	설명
doc	XMLType 형태로 출력된 DOM 형태의 문서

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    docNode   dbms_xmldom.DOMNode;
    n         dbms_xmldom.DOMNode;
    x         XMLType;
begin
    doc := dbms_xmldom.newDomDocument;
    docNode := dbms_xmldom.makeNode(doc);
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    n := dbms_xmldom.makeNode(ele);
    n := dbms_xmldom.appendChild(docNode, n);
    x := dbms_xmldom.getXMLType(doc);
    dbms_xmldom.freeDocument(doc);
end;
/

HASATTRIBUTE

해당 Element 노드가 특정 ATTRIBUTE를 가지고 있는지 확인하는 함수입니다.

HASATTRIBUTE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.HASATTRIBUTE
(
    elem       IN       DOMDocument,
    name       IN       VARCHAR2
)
RETURN BOOLEAN;

DBMS_XMLDOM.HASATTRIBUTE
(
    elem       IN       DOMDocument,
    name       IN       VARCHAR2,
    ns         IN       VARCHAR2
)
RETURN BOOLEAN;

• 파라미터

파라미터	설명
elem	해당 Attribute를 찾을 Element
name	Attribute의 이름
ns	Attribute의 네임스페이스

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    has_attr  BOOLEAN;
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    dbms_xmldom.setAttribute(ele, 'attr1', 'new_attribute');
    has_attr := dbms_xmldom.HasAttribute(ele, 'attr1');
    dbms_xmldom.freeDocument(doc);
end;
/

HASFEATURE

DOMImplementation에 특정 기능이 있는지 확인하는 함수입니다.

HASFEATURE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.HASFEATURE
(
    di           IN       DOMImplementation,
    feature      IN       VARCHAR2,
    version      IN       VARCHAR2
)
RETURN BOOLEAN;

• 파라미터

파라미터	설명
di	DOMImplementation
feature	확인할 기능
version	DOM 버전

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    impl      dbms_xmldom.DOMImplementation;
    feature   VARCHAR2(30);
    version   VARCHAR2(30);
begin
    doc := dbms_xmldom.newDomDocument;
    impl := dbms_xmldom.getImplementation(doc);
    feature := 'XML';
    version := '1.0';
    if dbms_xmldom.hasfeature(impl, feature, version) then
        dbms_output.put_line(feature || version);
    end if;
    dbms_xmldom.freeDocument(doc);
end;
/

IMPORTNODE

문서 안에 해당 노드를 복사하여 추가하는 함수입니다.

IMPORTNODE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.IMPORTNODE
(
    doc               IN       DOMDocument,
    importedNode      IN       DOMNode,
    deep              IN       BOOLEAN
)
RETURN DOMNode;

• 파라미터

파라미터	설명
doc	노드를 추가할 문서
importedNode	추가될 노드
deep	True : 해당 노드의 밑에 있는 모든 노드들을 추가 False : 해당 노드만 추가

• 예제

declare
    doc1       dbms_xmldom.DOMDocument;
    doc2       dbms_xmldom.DOMDocument;
    ele1       dbms_xmldom.DOMElement;
    ele2       dbms_xmldom.DOMElement;
    doc1Node   dbms_xmldom.DOMNode;
    n0         dbms_xmldom.DOMNode;
    n1         dbms_xmldom.DOMNode;
    n2         dbms_xmldom.DOMNode;
begin
    doc1 := dbms_xmldom.newDomDocument;
    doc2 := dbms_xmldom.newDomDocument;
    doc1Node := dbms_xmldom.makeNode(doc1);
    ele1 := dbms_xmldom.createElement(doc1, 'rootTag');
    ele2 := dbms_xmldom.createElement(doc1, 'ele');
    n1 := dbms_xmldom.appendChild(doc1Node, dbms_xmldom.makeNode(ele1));
    n2 := dbms_xmldom.appendChild(n1, dbms_xmldom.makeNode(ele2));
    n0 := dbms_xmldom.importNode(doc2, n1, FALSE);
    dbms_xmldom.freeDocument(doc1);
    dbms_xmldom.freeDocument(doc2);
end;
/

INSERTBEFORE

선택된 노드 앞에 해당노드를 추가하는 함수입니다. 선택된 노드가 Null일 경우, 해당 노드를 가장 끝에 추가합니다.

INSERTBEFORE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.INSERTBEFORE
(
    doc               IN       DOMDocument,
    importedNode      IN       DOMNode,
    deep              IN       BOOLEAN
)
RETURN DOMNode;

• 파라미터

파라미터	설명
n	추가될 노드의 부모 노드
newchild	노드에 추가될 자식 노드
refchild	refchild 앞에 newchild가 추가됨

• 예제

declare
    doc        dbms_xmldom.DOMDocument;
    ele        dbms_xmldom.DOMElement;
    ele1       dbms_xmldom.DOMElement;
    ele2       dbms_xmldom.DOMElement;
    ele3       dbms_xmldom.DOMElement;
    docNode    dbms_xmldom.DOMNode;
    nele       dbms_xmldom.DOMNode;
    n          dbms_xmldom.DOMNode;
    n1         dbms_xmldom.DOMNode;
    n2         dbms_xmldom.DOMNode;
begin
    doc  := dbms_xmldom.newDomDocument;
    docNode := dbms_xmldom.makeNode(doc);
    ele  := dbms_xmldom.createElement(doc, 'rootTag');
    ele1 := dbms_xmldom.createElement(doc, 'ele1');
    ele2 := dbms_xmldom.createElement(doc, 'ele2');
    ele3 := dbms_xmldom.createElement(doc, 'ele3');
    nele := dbms_xmldom.appendChild(docNode, dbms_xmldom.makeNode(ele));
    n1   := dbms_xmldom.appendChild(nele, dbms_xmldom.makeNode(ele1));
    n2   := dbms_xmldom.appendChild(nele, dbms_xmldom.makeNode(ele2));
    n := dbms_xmldom.insertBefore(nele, dbms_xmldom.makeNode(ele3), n1);
    dbms_xmldom.freeDocument(doc);
end;
/

INSERTDATA

DOMCharacterData의 특정 오프셋에 데이터를 추가합니다.

INSERTDATA 프러시저의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.INSERTDATA
(
    cd               IN      DOMCharacterData,
    offset           IN      NUMBER,
    arg              IN      VARCHAR2
);

• 파라미터

파라미터	설명
cd	DOMCharacterData
offset	데이터를 추가 할 위치
arg	추가할 데이터

• 예제

declare
    doc        dbms_xmldom.DOMDocument;
    txt        dbms_xmldom.DOMText;
    cd         dbms_xmldom.DOMCharacterData;
begin
    doc  := dbms_xmldom.newDomDocument;
    txt := dbms_xmldom.createTextNode(doc, 'node');
    cd := dbms_xmldom.makeCharacterData(dbms_xmldom.makenode(txt));
    dbms_xmldom.insertData(cd, 0, 'text');
    dbms_xmldom.freeDocument(doc);
end;
/

ISNULL

NULL 여부를 확인해주는 함수입니다.

ISNULL 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.ISNULL
(
    a       IN        DOMAttr
)
RETURN BOOLEAN;

DBMS_XMLDOM.ISNULL
(
    cds       IN        DOMCDataSection
)
RETURN BOOLEAN;

DBMS_XMLDOM.ISNULL
(
    cd       IN        DOMCharacterData
)
RETURN BOOLEAN;

DBMS_XMLDOM.ISNULL
(
    com       IN        DOMComment
)
RETURN BOOLEAN;

DBMS_XMLDOM.ISNULL
(
    doc       IN        DOMComment
)
RETURN BOOLEAN;

DBMS_XMLDOM.ISNULL
(
    df       IN        DOMDocumentFragment
)
RETURN BOOLEAN;

DBMS_XMLDOM.ISNULL
(
    dt       IN        DOMDocumentType
)
RETURN BOOLEAN;

DBMS_XMLDOM.ISNULL
(
    elem       IN        DOMElement
)
RETURN BOOLEAN;

DBMS_XMLDOM.ISNULL
(
    ent       IN        DOMEntity
)
RETURN BOOLEAN;

DBMS_XMLDOM.ISNULL
(
    eref       IN        DOMEntityReference
)
RETURN BOOLEAN;

DBMS_XMLDOM.ISNULL
(
    di       IN        DOMImplementation
)
RETURN BOOLEAN;

DBMS_XMLDOM.ISNULL
(
    nnm       IN        DOMNamedNodeMap
)
RETURN BOOLEAN;

DBMS_XMLDOM.ISNULL
(
    n       IN        DOMNode
)
RETURN BOOLEAN;

DBMS_XMLDOM.ISNULL
(
    nl       IN        DOMNodeList
)
RETURN BOOLEAN;

DBMS_XMLDOM.ISNULL
(
    nt       IN        DOMNotation
)
RETURN BOOLEAN;

DBMS_XMLDOM.ISNULL
(
    pi       IN        DOMProcessingInstruction
)
RETURN BOOLEAN;

DBMS_XMLDOM.ISNULL
(
    t       IN        DOMText
)
RETURN BOOLEAN;

• 파라미터

파라미터	설명
a	DOMAttr이 NULL인지 확인
cds	DOMCDataSection이 NULL인지 확인
cd	DOMCharacterData가 NULL인지 확인
com	DOMComment가 NULL인지 확인
doc	DOMDocument가 NULL인지 확인
df	DOMDocumentFragment가 NULL인지 확인
dt	DOMDocumentType이 NULL인지 확인
elem	DOMElement가 NULL인지 확인
ent	DOMEntity가 NULL인지 확인
eref	DOMEntityReference가 NULL인지 확인
di	DOMImplementation이 NULL인지 확인
nnm	DOMNamedNodeMap이 NULL인지 확인
n	DOMNode가 NULL인지 확인
nl	DOMNodeList가 NULL인지 확인
nt	DOMNotation이 NULL인지 확인
pi	DOMProcessingInstruction이 NULL인지 확인
t	DOMText가 NULL인지 확인

• 예제

declare
    doc        dbms_xmldom.DOMDocument;
begin
    dbms_xmldom.isNULL(doc);
    doc  := dbms_xmldom.newDomDocument;
    dbms_xmldom.isNULL(doc);
    dbms_xmldom.freeDocument(doc);
end;
/

ITEM

NamedNodeMap과 NodeList에서 해당 Item을 출력해주는 함수입니다.

ITEM 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.ITEM
(
    nl          IN        DOMNodeList,
    index       IN        Number
)
RETURN DOMNode;

DBMS_XMLDOM.ITEM
(
    nnm          IN        DOMNamedNodeMap,
    index        IN        Number
)
RETURN DOMNode;

• 파라미터

파라미터	설명
nl	Item을 가져올 NodeList
nnm	Item을 가져올 NamedNodeMap
index	가져올 Item의 Index

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    docNode   dbms_xmldom.DOMNode;
    p         dbms_xmldom.DOMNode;
    n         dbms_xmldom.DOMNode;
    nl        dbms_xmldom.DOMNodeList;
begin
    doc := dbms_xmldom.newDomDocument;
    docNode := dbms_xmldom.makeNode(doc);
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    p := dbms_xmldom.appendChild(docNode, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child1');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child2');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    ele := dbms_xmldom.createElement(doc, 'child3');
    n := dbms_xmldom.appendChild(p, dbms_xmldom.makeNode(ele));
    nl := dbms_xmldom.getChildNodes(p);
    n := dbms_xmldom.item(nl, 1);
    dbms_xmldom.freeDocument(doc);
end;
/

MAKECHARACTERDATA

노드를 DOMCharacterData로 캐스팅합니다.

MAKECHARACTERDATA 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.MAKECHARACTERDATA
(
    n          IN        DOMNode
)
RETURN DOMAttr;

• 파라미터

파라미터	설명
n	DOMCharacterData로 캐스팅할 DOMNode

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    txt       dbms_xmldom.DOMText;
    n         dbms_xmldom.DOMNode;
    cd        dbms_xmldom.DOMCharacterData;
begin
    doc := dbms_xmldom.newDomDocument;
    txt := dbms_xmldom.createTextNode(doc, 'DomText');
    n := dbms_xmldom.makeNode(txt);
    cd := dbms_xmldom.makeCharacterData(n);
    dbms_xmldom.freeDocument(doc);
end;
/

MAKEATTR

노드를 Attribute로 캐스팅합니다.

MAKEATTR 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.MAKEATTR
(
    n          IN        DOMNode
)
RETURN DOMAttr;

• 파라미터

파라미터	설명
n	DOMAttr로 캐스팅할 DOMNode

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    n         dbms_xmldom.DOMNode;
    attr      dbms_xmldom.DOMAttr;
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    dbms_xmldom.setAttribute(ele, 'attr1', 'new_attribute');
    attr := dbms_xmldom.getAttributeNode(ele, 'attr1');
    n := dbms_xmldom.makeNode(attr);
    attr := dbms_xmldom.makeAttr(n);
    dbms_xmldom.freeDocument(doc);
end;
/

MAKEDOCUMENT

노드를 Document로 캐스팅합니다.

MAKEDOCUMENT 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.MAKEDOCUMENT
(
    n          IN        DOMNode
)
RETURN DOMDocument;

• 파라미터

파라미터	설명
n	DOMDocument로 캐스팅할 DOMNode

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    root      dbms_xmldom.DOMNode;
begin
    doc := dbms_xmldom.newDomDocument;
    root := dbms_xmldom.makeNode(doc);
    doc := dbms_xmldom.makeDocument(root);
    dbms_xmldom.freeDocument(doc);
end;
/

MAKEELEMENT

노드를 Element로 캐스팅합니다.

MAKEELEMENT 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.MAKEELEMENT
(
    n          IN        DOMNode
)
RETURN DOMElement;

• 파라미터

파라미터	설명
n	DOMElement로 캐스팅할 DOMNode

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    n         dbms_xmldom.DOMNode;
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    n := dbms_xmldom.makeNode(ele);
    ele := dbms_xmldom.makeElement(n);
    dbms_xmldom.freeDocument(doc);
end;
/

MAKENODE

Document, DOMAttr 등을 DOMNode로 캐스팅합니다.

MAKENODE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.MAKENODE
(
    a          IN        DOMAttr
)
RETURN DOMNode;

DBMS_XMLDOM.MAKENODE
(
    cds          IN        DOMCDataSection
)
RETURN DOMNode;

DBMS_XMLDOM.MAKENODE
(
    cd       IN        DOMCharacterData
)
RETURN DOMNode;

DBMS_XMLDOM.MAKENODE
(
    com       IN        DOMComment
)
RETURN DOMNode;

DBMS_XMLDOM.MAKENODE
(
    doc       IN        DOMComment
)
RETURN DOMNode;

DBMS_XMLDOM.MAKENODE
(
    df       IN        DOMDocumentFragment
)
RETURN DOMNode;

DBMS_XMLDOM.MAKENODE
(
    dt       IN        DOMDocumentType
)
RETURN DOMNode;

DBMS_XMLDOM.MAKENODE
(
    elem       IN        DOMElement
)
RETURN DOMNode;

DBMS_XMLDOM.MAKENODE
(
    ent       IN        DOMEntity
)
RETURN DOMNode;

DBMS_XMLDOM.MAKENODE
(
    eref       IN        DOMEntityReference
)
RETURN DOMNode;

DBMS_XMLDOM.MAKENODE
(
    n       IN        DOMNotation
)
RETURN DOMNode;

DBMS_XMLDOM.MAKENODE
(
    pi       IN        DOMProcessingInstruction
)
RETURN DOMNode;

DBMS_XMLDOM.MAKENODE
(
    t       IN        DOMText
)
RETURN DOMNode;

• 파라미터

파라미터	설명
a	DOMNode로 캐스팅할 DOMAttr
cds	DOMNode로 캐스팅할 DOMCDataSection
cd	DOMNode로 캐스팅할 DOMCharacterData
com	DOMNode로 캐스팅할 DOMComment
doc	DOMNode로 캐스팅할 DOMDocument
df	DOMNode로 캐스팅할 DOMDocumentFragment
dt	DOMNode로 캐스팅할 DOMDocumentType
elem	DOMNode로 캐스팅할 DOMElement
ent	DOMNode로 캐스팅할 DOMEntity
eref	DOMNode로 캐스팅할 DOMEntityReference
n	DOMNode로 캐스팅할 DOMNotation
pi	DOMNode로 캐스팅할 DOMProcessingInstruction
t	DOMNode로 캐스팅할 DOMText

• 예제

declare
    doc          dbms_xmldom.DOMDocument;
    docNode      dbms_xmldom.DOMNode;
begin
    doc := dbms_xmldom.newDomDocument;
    docNode := dbms_xmldom.makeNode(doc);
    dbms_xmldom.freeDocument(doc);
end;
/

NEWDOMDOCUMENT

DOM 형태의 문서를 생성합니다.

NEWDOMDOCUMENT 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.NEWDOMDOCUMENT
RETURN DOMDocument;

DBMS_XMLDOM.NEWDOMDOCUMENT
(
    xmldoc       IN        SYS.XMLTYPE
)
RETURN DOMDocument;

DBMS_XMLDOM.NEWDOMDOCUMENT
(
    cl       IN        CLOB
)
RETURN DOMDocument;

• 파라미터

파라미터	설명
xmldoc	DOMDocument를 생성할 입력값
cl	DOMDocument를 생성할 입력값

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
begin
    doc := dbms_xmldom.newDomDocument;
    dbms_xmldom.freeDocument(doc);
end;
/

REMOVEATTRIBUTE

해당 Element노드의 특정 ATTRIBUTE를 제거하는 프러시저입니다.

REMOVEATTRIBUTE 프러시저의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.REMOVEATTRIBUTE
(
    elem     IN        DOMElement,
    name     IN        VARCHAR2
);

DBMS_XMLDOM.REMOVEATTRIBUTE
(
    elem     IN        DOMElement,
    name     IN        VARCHAR2,
    ns       IN        VARCHAR2
);

• 파라미터

파라미터	설명
elem	해당 Attribute를 찾을 Element
name	Attribute의 이름
ns	Attribute의 네임스페이스

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    dbms_xmldom.setAttribute(ele, 'attr1', 'new_attribute');
    dbms_xmldom.removeAttribute(ele, 'attr1');
    dbms_xmldom.freeDocument(doc);
end;
/

REMOVECHILD

해당 노드의 자식 노드를 제거하는 함수입니다.

REMOVECHILD 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.REMOVECHILD
(
    n            IN        DOMNode,
    oldchild     IN        DOMNode
)
RETURN DOMNode;

• 파라미터

파라미터	설명
n	자식 노드를 가지고 있는 노드
oldchild	지워질 자식 노드

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    docNode   dbms_xmldom.DOMNode;
    nele      dbms_xmldom.DOMNode;
    deleted   dbms_xmldom.DOMNode;
begin
    doc := dbms_xmldom.newDomDocument;
    docNode := dbms_xmldom.makeNode(doc);
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    nele := dbms_xmldom.makeNode(ele);
    nele := dbms_xmldom.appendChild(docNode, nele);
    deleted := dbms_xmldom.removeChild(docNode, nele);
    dbms_xmldom.freeDocument(doc);
end;
/

REPLACECHILD

해당 노드의 자식 노드를 교체하는 함수입니다.

REPLACECHILD 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.REPLACECHILD
(
    n            IN        DOMNode,
    newchild     IN        DOMNode,
    oldchild     IN        DOMNode
)
RETURN DOMNode;

• 파라미터

파라미터	설명
n	자식 노드를 가지고 있는 노드
newchild	새로 넣을 자식 노드
oldchild	바꿔질 자식 노드

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele1      dbms_xmldom.DOMElement;
    ele2      dbms_xmldom.DOMElement;
    docNode   dbms_xmldom.DOMNode;
    nele1     dbms_xmldom.DOMNode;
    nele2     dbms_xmldom.DOMNode;
    replaced  dbms_xmldom.DOMNode;
begin
    doc := dbms_xmldom.newDomDocument;
    docNode := dbms_xmldom.makeNode(doc);
    ele1 := dbms_xmldom.createElement(doc, 'rootTag');
    ele2 := dbms_xmldom.createElement(doc, 'newroot');
    nele1 := dbms_xmldom.makeNode(ele1);
    nele2 := dbms_xmldom.makeNode(ele2);
    nele1 := dbms_xmldom.appendChild(docNode, nele1);
    replaced := dbms_xmldom.replaceChild(docNode, nele2, nele1);
    dbms_xmldom.freeDocument(doc);
end;
/

REPLACEDATA

DOMCharacterData의 특정 범위의 데이터를 변경합니다.

REPLACEDATA 프러시저의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.REPLACEDATA
(
    cd            IN       DOMCharacterData,
    offset        IN       NUMBER,
    cnt           IN       NUMBER,
    arg           IN       VARCHAR2
);

• 파라미터

파라미터	설명
cd	DOMCharacterData
offset	변경할 데이터의 오프셋
cnt	교체될 문자의 개수
arg	교체할 값

• 예제

declare
    doc        dbms_xmldom.DOMDocument;
    txt        dbms_xmldom.DOMText;
    cd         dbms_xmldom.DOMCharacterData;
begin
    doc  := dbms_xmldom.newDomDocument;
    txt := dbms_xmldom.createTextNode(doc, 'node');
    cd := dbms_xmldom.makeCharacterData(dbms_xmldom.makenode(txt));
    dbms_xmldom.setData(cd, 'text');
    dbms_xmldom.replacedata(cd, 2, 1, 's');
    dbms_xmldom.freeDocument(doc);
end;
/

SETATTRIBUTE

특정 Element에 Attribute를 추가하는 프러시저입니다다.

SETATTRIBUTE 프러시저의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.SETATTRIBUTE
(
    elem           IN       DOMElement,
    name           IN       VARCHAR2,
    newvalue       IN       VARCHAR2
);

DBMS_XMLDOM.SETATTRIBUTE
(
    elem           IN       DOMElement,
    name           IN       VARCHAR2,
    newvalue       IN       VARCHAR2
    ns             IN       VARCHAR2
);

• 파라미터

파라미터	설명
elem	해당 Attribute를 넣을 Element
name	Attribute의 이름
newvalue	Attribute의 값
ns	Attribute의 네임스페이스

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    n         dbms_xmldom.DOMNode;
    attr_val  VARCHAR2(20);
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    dbms_xmldom.setAttribute(ele, 'attr1', 'new_attribute');
    attr_val := dbms_xmldom.getAttribute(ele, 'attr1');
    dbms_output.put_line(attr_val);
    dbms_xmldom.freeDocument(doc);
end;
/

SETATTRIBUTENODE

특정 Element에 Attribute를 추가하는 함수입니다.

SETATTRIBUTENODE 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.SETATTRIBUTENODE
(
    elem           IN       DOMElement,
    attr           IN       VARCHAR2
)
RETURN DOMAttr;

• 파라미터

파라미터	설명
elem	해당 Attribute를 넣을 Element
attr	추가할 DOMAttr

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    attr      dbms_xmldom.DOMAttr;
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    attr := dbms_xmldom.createAttribute(doc, 'mytag');
    attr := dbms_xmldom.setAttributeNode(ele, attr);
    dbms_xmldom.freeDocument(doc);
end;
/

SETDATA

DOMCharacterData를 세팅합니다.

SETDATA 프러시저의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.SETDATA
(
    cd           IN      DOMCharacterData,
    data         IN      VARCHAR2
);

• 파라미터

파라미터	설명
cd	DOMCharacterData
data	세팅할 데이터

• 예제

declare
    doc        dbms_xmldom.DOMDocument;
    txt        dbms_xmldom.DOMText;
    cd         dbms_xmldom.DOMCharacterData;
begin
    doc  := dbms_xmldom.newDomDocument;
    txt := dbms_xmldom.createTextNode(doc, 'node');
    cd := dbms_xmldom.makeCharacterData(dbms_xmldom.makenode(txt));
    dbms_xmldom.setData(cd, 'text');
    dbms_xmldom.freeDocument(doc);
end;
/

SETNODEVALUE

노드의 값을 변경하는 프러시저입니다.

SETNODEVALUE 프러시저의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.SETNODEVALUE
(
    n           IN     DOMNode,
    value       IN     VARCHAR2
);

• 파라미터

파라미터	설명
n	값을 변경할 노드
value	노드에 적용할 값

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    attr      dbms_xmldom.DOMAttr;
    n         dbms_xmldom.DOMNode;
begin
    doc := dbms_xmldom.newDomDocument;
    attr := dbms_xmldom.createAttribute(doc, 'attr');
    n := dbms_xmldom.makeNode(attr);
    dbms_xmldom.setNodeValue(n, 'value');
    dbms_xmldom.freeDocument(doc);
end;
/

SETVALUE

Attribute 노드의 값을 변경하는 프러시저입니다.

SETVALUE 프러시저의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.SETVALUE
(
    a         IN    DOMAttr,
    value     IN    VARCHAR2
);

• 파라미터

파라미터	설명
a	값을 변경할 Attribute 노드
value	Attribute에 적용할 값

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    attr      dbms_xmldom.DOMAttr;
begin
    doc := dbms_xmldom.newDomDocument;
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    dbms_xmldom.setAttribute(ele, 'attr1', 'new_attribute');
    attr := dbms_xmldom.getAttributeNode(ele, 'attr1');
    dbms_xmldom.setValue(attr, 'new_attr');
    dbms_xmldom.freeDocument(doc);
end;
/

SPLITTEXT

DOMText를 두개로 분리합니다.

SPLITTEXT 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.SPLITTEXT
(
    t          IN    DOMText,
    offset     IN    NUMBER
)
RETURN DOMText;

• 파라미터

파라미터	설명
t	DOMText
offset	분리할 데이터의 오프셋

• 예제

declare
    doc        dbms_xmldom.DOMDocument;
    txt        dbms_xmldom.DOMText;
    st         dbms_xmldom.DOMText;
begin
    doc  := dbms_xmldom.newDomDocument;
    txt := dbms_xmldom.createTextNode(doc, 'textnode');
    st := dbms_xmldom.splitText(txt, 4);
    dbms_xmldom.freeDocument(doc);
end;
/

SUBSTRINGDATA

DOMCharacterData에서 특정 범위의 데이터를 출력합니다.

SUBSTRINGDATA 함수의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.SUBSTRINGDATA
(
    cd          IN    DOMCharacterData,
    offset      IN    NUMBER,
    cnt         IN    NUMBER
)
RETURN VARCHAR2;

• 파라미터

파라미터	설명
cd	DOMCharacterData
offset	DOMCharacterData에서 출력할 데이터의 시작 위치
cnt	DOMCharacterData에서 출력할 데이터의 개수

• 예제

declare
    doc        dbms_xmldom.DOMDocument;
    txt        dbms_xmldom.DOMText;
    cd         dbms_xmldom.DOMCharacterData;
begin
    doc  := dbms_xmldom.newDomDocument;
    txt := dbms_xmldom.createTextNode(doc, 'textnode');
    cd := dbms_xmldom.makeCharacterData(dbms_xmldom.makenode(txt));
    dbms_output.put_line(dbms_xmldom.substringData(cd, 0, 4));
    dbms_xmldom.freeDocument(doc);
end;
/

WRITETOBUFFER

DOM 문서를 VARCHAR2 형태로 출력합니다.

WRITETOBUFFER 프러시저의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.WRITETOBUFFER
(
    n          IN         DOMNode,
    buffer     IN OUT     VARCHAR2
);

DBMS_XMLDOM.WRITETOBUFFER
(
    doc          IN         DOMDocument,
    buffer       IN OUT     VARCHAR2
);

• 파라미터

파라미터	설명
n	DOMNode
buffer	문서가 출력될 공간
doc	DOMDocument

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    buf       VARCHAR2(100);
begin
    doc := dbms_xmldom.newDomDocument('<root></root>');
    dbms_xmldom.writeToBuffer(doc, buf);
    dbms_xmldom.freeDocument(doc);
end;
/

WRITETOCLOB

DOM 문서를 CLOB 형태로 출력합니다.

WRITETOCLOB 프러시저의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.WRITETOCLOB
(
    doc     IN    DOMDocument,
    cl      OUT    CLOB
);

DBMS_XMLDOM.WRITETOCLOB
(
    n      IN     DOMNode,
    cl     OUT    CLOB
);

• 파라미터

파라미터	설명
doc	DOM 형태의 문서
n	DOM 문서의 노드
cl	결과가 출력될 CLOB

• 예제

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    docNode   dbms_xmldom.DOMNode;
    n         dbms_xmldom.DOMNode;
    cl        CLOB;
begin
    doc := dbms_xmldom.newDomDocument;
    docNode := dbms_xmldom.makeNode(doc);
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    n := dbms_xmldom.makeNode(ele);
    n := dbms_xmldom.appendChild(docNode, n);
    dbms_lob.createTemporary(cl, false);
    dbms_xmldom.writeToClob(doc, cl);
    dbms_xmldom.freeDocument(doc);
end;
/

WRITETOFILE

DOM 문서를 파일로 출력합니다.

WRITETOFILE 프러시저의 세부 내용은 다음과 같습니다.

• 프로토타입

DBMS_XMLDOM.WRITETOFILE
(
    doc          IN    DOMDocument,
    filename     IN    VARCHAR2
);

DBMS_XMLDOM.WRITETOFILE
(
    n            IN   DOMNode,
    filename     IN   VARCHAR2
);

DBMS_XMLDOM.WRITETOFILE
(
    doc          IN    DOMDocument,
    filename     IN    VARCHAR2,
    charset      IN    VARCHAR2
);

DBMS_XMLDOM.WRITETOFILE
(
    n            IN    DOMNode,
    filename     IN    VARCHAR2,
    charset      IN    VARCHAR2
);

• 파라미터

파라미터	설명
doc	DOM 형태의 문서
n	DOM 문서의 노드
filename	결과를 출력할 파일 경로
charset	결과 문자열의 charset

• 예제

create or replace directory xmlfolder as '/tmp';

declare
    doc       dbms_xmldom.DOMDocument;
    ele       dbms_xmldom.DOMElement;
    docNode   dbms_xmldom.DOMNode;
    n         dbms_xmldom.DOMNode;
    cl        CLOB;
begin
    doc := dbms_xmldom.newDomDocument;
    docNode := dbms_xmldom.makeNode(doc);
    ele := dbms_xmldom.createElement(doc, 'rootTag');
    n := dbms_xmldom.makeNode(ele);
    n := dbms_xmldom.appendChild(docNode, n);
    dbms_lob.createTemporary(cl, false);
    dbms_xmldom.writeToFile(doc, 'XMLFOLDER/test.xml');
    dbms_xmldom.freeDocument(doc);
end;
/